note
Tux
<p>You are heading for disaster by stripping the <c>"</c>'s from "summary". If there are <c>,</c>'s in the summary, your CSV will be corrupt. Another point is that not all records seem to have the same fields defined. One could do better by being more generic. And finally, use a decent CSV module for output like [mod://Text::CSV_XS] or [mod://Text::CSV].</p>
<code>
#!/usr/bin/perl
use 5.014;
use warnings;
use Text::CSV_XS;
my %hdr;
my @dta;
my $csv = Text::CSV_XS->new ({ binary => 1, auto_diag => 1, eol => "\r\n" });
{ local $/ = "";
while (<DATA>) {
my %data = m/^\s*(\w[^ :]+)[: ]+(.*\S)\s*$/gm;
$hdr{$_}++ for keys %data;
push @dta, \%data;
}
my @hdr = keys %hdr;
$csv->print (*STDOUT, \@hdr);
$csv->print (*STDOUT, [ @{$_}{@hdr} ]) for @dta;
}
__END__
user: myus44 [up]
------------
admin-state enabled
summary "Johnny Cash"
access-level group-defined
group mi-group [up]
user: jar1543 [up]
------------
admin-state enabled
summary "Lara Croft"
access-level group-defined
group jar-head [up]
user: myprivilegeduser [up]
-----------
admin-state enabled
access-level privileged
</code>
<p>will produce:</p>
<code>
group,summary,user,access-level,admin-state
"mi-group [up]","""Johnny Cash""","myus44 [up]",group-defined,enabled
"jar-head [up]","""Lara Croft""","jar1543 [up]",group-defined,enabled
,,"myprivilegeduser [up]",privileged,enabled
</code>
<p>This way the data is exactly what it was. If you do not want the double quotes, but still be safe:</p>
<code>
while (<DATA>) {
my %data = m/^\s*(\w[^ :]+)[: ]+(.*\S)\s*$/gm;
$hdr{$_}++ for keys %data;
s/^"(.*)"$/$1/ for values %data;
push @dta, \%data;
}
</code>
<p>To produce</p>
<code>
group,summary,user,access-level,admin-state
"mi-group [up]","Johnny Cash","myus44 [up]",group-defined,enabled
"jar-head [up]","Lara Croft","jar1543 [up]",group-defined,enabled
,,"myprivilegeduser [up]",privileged,enabled
</code>
<p>And finally, if you want the <c>user</c> as first/key field, proceed like</p>
<code>
delete $hdr{user};
my @hdr = ("user", keys %hdr);
</code>
<p>to get</p>
<code>
user,group,summary,access-level,admin-state
"myus44 [up]","mi-group [up]","Johnny Cash",group-defined,enabled
"jar1543 [up]","jar-head [up]","Lara Croft",group-defined,enabled
"myprivilegeduser [up]",,,privileged,enabled
</code>
<p>Side note: [mod://Text::CSV_XS] will have no problems with undefined fields</p>
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-200365">
<br />
Enjoy, Have FUN! H.Merijn
</div></div>
1047505
1047508