Why isn't this simple method to join elements of 2 arrays not working

[Axlex]

Hello wise Monks; i am trying to concatenate the lines of 2 files and came up with this simple code

my (@In, $In, @Out, $Out, $InFile, $OutFile);                         
+       # declare variables
    open $InFile, "<", "e:/File1.txt";            # open the exported 
+file in read mode
    open $OutFile, ">>", "e:/File2";
    @In = <$InFile>;
    @Out = <$OutFile>;
    close $InFile;
    close $OutFile;
    for my $k ( 0 .. $#In ) {
        $Out[$k] = "$Out[$k],$In[$k]";
}
    open $OutFile, ">", "e:/File2.txt";            # open the outfile,
+ deleting all content (writemode)
    print $OutFile @Out;
    close $OutFile;

but i am getting the error: "Use of uninitialized value within @Out in concatenation(.) or string at join.pl"

I know, my programming skills are bad but please, i dont know any other way.

[ikegami]

You are trying to read from a file you opened for writing.

[LanX]

open $OutFile, ">>", "e:/File2";

Is wrong, use "<" to read, @Out must be empty otherwise.

">>" means appending !

[davido]

Just for fun...

use strict;
use warnings;
use autodie;

use Getopt::Long;
use File::Slurp qw( read_file write_file );
use List::MoreUtils 'pairwise';

use constant {
  EMPTY => q{},
  FILE1 => 'e:/File1.txt',
  FILE2 => 'e:/File2.txt'
};

my $LIVE = EMPTY;
GetOptions('live' => \$LIVE);


write_file
  $LIVE ? FILE2 : \*STDOUT,
  pairwise {
    join( ',', map{$_//EMPTY} $a,$b ) . "\n";
  } @{slurp(FILE1)}, @{slurp(FILE2)};


sub slurp { read_file shift, array_ref=> 1, chomp => 1 }

By default this will dump its output to STDOUT. Once you're certain it will do what you want, run it with the --live flag, and it will overwrite FILE2, which seems to be what you want. I'd probably use copies of the original files until I'm certain.

Updated: Handle command-line option via Getopt::Long rather than @ARGV.