Print keys corresponding to duplicate values

[amar712]

I have a hash %hash = { 'a' => 1, 'b' => 2, 'c' => '1', 'd' => 3, 'e' => '5' } How can I return the keys with the same value. In the above example I want a,c.

[NetWallah]

use strict;
use warnings;
use feature 'say';
my %hash = ( 'a' => 1, 'b' => 2, 'c' => '1', 'd' => 3,
             'e' => '5');
  my (%seen,@dups); 
  while (my($k,$v)=each %hash){
    if ( defined $seen{$v}){
      push @dups,$k;
      $seen{$v} and push @dups,$seen{$v};
      $seen{$v}='';
      next
    }
    $seen{$v}=$k
  }
say for sort @dups;
__OUTPUT__
a
c

[davido]

This solution inverts the hash like this:

 k1   v1 k2   v2 k3   v1     v1           v2
(a => 1, b => 2, c => 1) => (1  => [a,c], 2 => [b])

Then it just becomes a matter of finding those value-keys who point to more than a single original key name.

use strict;
use warnings;

my %hash = (a => 1, b => 2, c => 1, d => 3, e => 5);

my @non_unique = duplicated_values_keys(%hash);

print "$_\n" for @non_unique;

sub duplicated_values_keys {
    my %hash = @_;
    my %inverted;
    push @{$inverted{$hash{$_}}}, $_ for keys %hash;
    return map {@{$inverted{$_}} > 1 ? @{$inverted{$_}} : ()} keys %in
+verted;
}

Outputs:

a
c

...in no particular order.

[FreeBeerReekingMonk]

You need to loop through your keys, and check if your values are the same. Usually one uses another hash %SEEN to store the reverse: value-to-key (instead of key-to-value) while looping over the keys...

ANOTHER idea is to loop over the values:

for my $val (values %hash){

And detect FIRST which ones you already seen (using %SEEN in a numerical fashion), before looping through the keys and knowing the value, look it up if you seen it already.

Also, write your hash definition like this:

use strict;
use warnings;
my %hash = ( 'a' => 1, 'b' => 2, 'c' => '1', 'd' => 3, 'e' => '5' );

keys

[tangent]

As FreeBeerReekingMonk suggests, the %seen style of hash is often used for counting duplicates:

my %seen;
$seen{$_}++ for values %hash;
my @dups = grep { $seen{ $hash{$_} } > 1 } keys %hash;
print join(',', sort @dups );

[Anonymous Monk]

see perlfaq, perldoc -q "hash.*dupli"