Create based on repeating data

[Perl-Thornton]

Hello all. I have a file that looks like this:

Hostname1     1.1.1.1     Cisco
              Chassis Serial Number xyz123
              Interface Gig0/0/31
Hostname2     2.2.2.2     Juniper
              Chassis Serial Number abc123
              Interface Gi-0/0/31

The repeating pattern seems obvious. Each row starts with either text that starts at the beginning of the row (i.e. hostname which could be the key to a hash), or the row starts with white space or tabs and then some text which could be the values associated with the key of the hash (i.e. serial number, interface, etc..). I have been working on solving this to parse through files with a Perl program but I've failed so far. I was hoping the Perl community might have suggestions to help me grasp what seems like should be a simple concept.

[BrowserUk]

Like this?:

#! perl -slw
use strict;
use Data::Dump qw[ pp ];

my( %data, %subhash, $last );
while( <DATA> ) {
    if( /^H/ ) {
        if( $last ) {
            $data{ $last } = { %subhash };
           undef %subhash;
       }
        ( $last, my( $key, $val ) ) = m[(\S+)\s+(.+)\s+(\S+)$];
        $subhash{ $key } = $val;
    }
    else {
        my( $key, $val ) = m[^\s+(.+)\s+(\S+)$];
        $subhash{ $key } = $val;
    }
}
$data{ $last } = { %subhash };

pp \%data;

__DATA__
Hostname1     1.1.1.1     Cisco
              Chassis Serial Number xyz123
              Interface Gig0/0/31
Hostname2     2.2.2.2     Juniper
              Chassis Serial Number abc123
              Interface Gi-0/0/31

Outputs:

C:\test>1170268.pl
{
  Hostname1 => {
                 "1.1.1.1    " => "Cisco",
                 "Chassis Serial Number" => "xyz123",
                 Interface => "Gig0/0/31",
               },
  Hostname2 => {
                 "2.2.2.2    " => "Juniper",
                 "Chassis Serial Number" => "abc123",
                 Interface => "Gi-0/0/31",
               },
}

[NetWallah]

Avoiding the assumption that hostnames start with "H", and simplifying logic:

#! perl -slw
use strict;
use Data::Dumper;

my( @data, $current );
while( <DATA> ) {
    if( my ($host,$ip,$brand) =/^(\w+)\s+(\S+)\s+(\S+)/ ) {
        $current and push @data, $current;
        $current = {HOST=>$host, IP=>$ip, BRAND=>$brand};
        next;
    }
    my( $key, $val )  = m[\s+(.+)\s+(\S+)$] or next;
    $current->{$key} = $val;
}
$current and push @data, $current;

print Dumper \@data;

__DATA__
Hostname1     1.1.1.1     Cisco
              Chassis Serial Number xyz123
              Interface Gig0/0/31
Hostname2     2.2.2.2     Juniper
              Chassis Serial Number abc123
              Interface Gi-0/0/31

Output:

$VAR1 = [
          {
            'Chassis Serial Number' => 'xyz123',
            'Interface' => 'Gig0/0/31',
            'BRAND' => 'Cisco',
            'HOST' => 'Hostname1',
            'IP' => '1.1.1.1'
          },
          {
            'HOST' => 'Hostname2',
            'BRAND' => 'Juniper',
            'Chassis Serial Number' => 'abc123',
            'Interface' => 'Gi-0/0/31',
            'IP' => '2.2.2.2'
          }
        ];

Alternative, using hostname as a key to a hash:

 my ($current,%data)
...
        $current and $data{$current->{HOST}} = $current; # in 2 places
        $current = {HOST=>$host, IP=>$ip, BRAND=>$brand};

[GrandFather]

Show us what you have tried. Show us the expected output. Tell us how it fails.

The data you show is great in terms of size. Does it show any special cases you may need to deal with?

[perldigious]

Hi Perl-Thornton,

I'm not quite understanding your question, perhaps you could add a little more to clarify for me and the rest of the monastery?

You say you are trying to parse through the file, but what are you trying to extract exactly?