Re: Hash Multiple values for a key-Filtering unique values for a key in hash

That's a FAQ: How can I remove duplicate elements from a list or array?.

To keep the values unique for a specific key, without removing duplicates from the values of other keys, you'll need to clear the %seen hash for each arrayref value. Here's how you might implement that:

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dump;

my $HASH1 = {
'Alabama' => ['Andalusia', 'Anniston', 'Clanton', 'Eufaula', 'Auburn',
+ 'Bessemer', 'Eufaula', 'Auburn', 'Bessemer' ],
'California' => ['Barstow','Barstow'],
'Georgia' => ['Darien'],
'New York' => ['Amsterdam','Coney Island','Coney Island','Beacon','Bec
+on']
};

for (values %$HASH1) {
    my %seen;
    $_ = [ grep { ! $seen{$_}++ } @$_ ];
}

dd $HASH1;
[download]

Output:

{
  "Alabama"    => [
                    "Andalusia",
                    "Anniston",
                    "Clanton",
                    "Eufaula",
                    "Auburn",
                    "Bessemer",
                  ],
  "California" => ["Barstow"],
  "Georgia"    => ["Darien"],
  "New York"   => ["Amsterdam", "Coney Island", "Beacon", "Becon"],
}
[download]

Note that the input shown in your OP has the two unique values 'Beacon' and 'Becon', but your expected output only has 'Becon': I suspect a typo. Beyond that, my actual output matches your expected output.


Keep It Simple, Stupid
	PerlMonks