Perl not able to read file

[Anonymous Monk]

The last line of the following program is not able to read the file

Data file = MultiLineData.txt
19760        Austria    7800    Kingsland    124 Petrie Terrace
19762                    
19764                    
19765                    
19767        Austria    7864    Kingsland    1/249 Coronation Drive
19768                    
19770        Austria    7853    Kingsland    Lawrence:
103 Frasers Rd
19771                    
19775        Austria    7800    Kingsland    127 Edward Street
19777                    
19779                    
19780        Austria    7963    Kingsland    133 King Street
19782                    
19784                    
19785                    
19787                    
19789                    
19791        Austria    7800    Kingsland    Riverside Centre
Level 29 123 Eagle Street
19793                    
19795                    
19796                    
19799                    
67301                    
67302                    
67304        Austria    7810    Kingsland    Argyle Office
Suit 9 20 Argyle Street
67306                    
67308

use strict;
use warnings;
 
my $dir = 'C:\Scripts';  
  
open(my $fh1, '<', "$dir\\MultiLineData.txt") or die $!;
open(my $out1, '>', "$dir\\work.txt") or die $!;
open(my $fh2, '<', "$dir\\work.txt") or die $!;

while (my $row = <$fh1>) {
    chomp $row;
    my $str = $row;
    $str =~ s/\t/|/g;
    print $out1 "$str\n";
}

while (<$fh2>){chomp $_; print "$_\n"};

[choroba]

If you want to read from a file you've just written to, you need to close the file after you're finished writing to it.

[Laurent_R]

It is probably not needed to close the filehandle. From the close documentation:

You don't have to close FILEHANDLE if you are immediately going to do another open on it, because open closes it for you. (See open.)

Having said that, I would still explicitly close the file handle before reopening it. This looks cleaner and more understandable.

But the important point is that reopening the file for reading needs to be done after all required data has been printed to it.

An additional comment on the OP code is that there is no need to chomp the input line if the next statement adds a \n to it.

[choroba]

> You don't have to close FILEHANDLE if you are immediately going to do another open on it

Yes, but there's no open going on the same filehandle, there is another filehandle opened for the same file .

Try commenting the indicated line:

#!/usr/bin/perl
use warnings;
use strict;

open my $OUT, '>', '1' or die $!;
open my $IN,  '<', '1' or die $!;
print {$OUT} "$_\n" for 1 .. 20;
close $OUT or die $!;  # <- Comment me!
print while <$IN>;

It's true that I'd rather open the filehandle later before reading from it, not at the top of the script, but even in such situation you need to close the output filehandle before reading from the file.

[Corion]

How do you know that it is unable to read the second file?

What happens? What did you expect to happen?

You cannot open the same file for reading and writing at the same time. If you want to read what you just wrote, you will also need to look at seek and flush to synchronize the two filehandles.

Why do you want to read what you just wrote at all?

[thanos1983]

Hello Anonymous Monk,

Fellow monks have provided you a solution to your problem. But why not use a module like File::Slurper that will do all the work for you in the background and possibly more efficiently also.

Take a look I think it will help you to minimize your errors/problems.

Update: I assume you want also to skip lines that do not have any valuable content, something like that?

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;
use feature 'say';
use File::Slurper 'read_lines';
use Scalar::Util qw(looks_like_number);

my @content = read_lines('in.txt');
print Dumper \@content;

my @final;
foreach my $line (@content) {
    $line =~s/\s+/ /g ;
    next if (looks_like_number($line));
    push @final, $line;
}

print Dumper \@final;

__END__

$ perl test.pl
$VAR1 = [
          '19760        Austria    7800    Kingsland    124 Petrie Ter
+race',
          '19762                    ',
          '19764                    ',
          '19765                    ',
          '19767        Austria    7864    Kingsland    1/249 Coronati
+on Drive',
          '19768                    ',
          '19770        Austria    7853    Kingsland    Lawrence:    1
+03 Frasers Rd',
          '19771                    ',
          '19775        Austria    7800    Kingsland    127 Edward Str
+eet',
          '19777                    ',
          '19779                    ',
          '19780        Austria    7963    Kingsland    133 King Stree
+t',
          '19782                    ',
          '19784                    ',
          '19785                    ',
          '19787                    ',
          '19789                    ',
          '19791        Austria    7800    Kingsland    Riverside Cent
+re Level 29 123 Eagle Street',
          '19793                    ',
          '19795                    ',
          '19796                    ',
          '19799                    ',
          '67301                    ',
          '67302                    ',
          '67304        Austria    7810    Kingsland    Argyle Office 
+Suit 9 20 Argyle Street',
          '67306                    ',
          '67308'
        ];
$VAR1 = [
          '19760 Austria 7800 Kingsland 124 Petrie Terrace',
          '19767 Austria 7864 Kingsland 1/249 Coronation Drive',
          '19770 Austria 7853 Kingsland Lawrence: 103 Frasers Rd',
          '19775 Austria 7800 Kingsland 127 Edward Street',
          '19780 Austria 7963 Kingsland 133 King Street',
          '19791 Austria 7800 Kingsland Riverside Centre Level 29 123 
+Eagle Street',
          '67304 Austria 7810 Kingsland Argyle Office Suit 9 20 Argyle
+ Street'
        ];

Then simply use File::Slurper/write_text($filename,_$content,_$encoding,_$crlf) and put your data into a file instead of my array that I placed in the code for demonstration purposes.

Hope this helps, BR.