Beefy Boxes and Bandwidth Generously Provided by pair Networks
Welcome to the Monastery
 
PerlMonks  

pat - find words by matching pattern (for crypto)

by merlyn (Sage)
on Aug 21, 2000 at 07:26 UTC ( #28764=sourcecode: print w/ replies, xml ) Need Help??

Category: Cryptography
Author/Contact Info Randal L. Schwartz, merlyn
Description: Usage: pat ABCABC finds any word that has three repeated characters twice in a row (such as "murmur" in my dictionary). pat XYYX finds words that are four-character palindromes, such as "deed". In the result, X and Y must be different. So pat ABCDEFGHAB finds ten-letter words whose first two and last two characters are identical, but the remaining letters are all distinct, such as "thousandth" or "Englishmen".

To require literal characters, use lowercase, as in pat fXXd, requiring an f, two identical letters, and a d, such as "food" or "feed".

For grins, dumps the regex that the pattern has been transformed into, so you can write your own, or see how much work you're avoiding by using this program.

  "Fun for the entire family!" -- Rolling Stone magazine (but not about this program)

#!/usr/bin/perl -w
use strict;

open WORDS, "/usr/dict/words" or die "no more words: $!";

for (@ARGV) {
  my @avoid = do {
    my @lits = /[a-z]/g;
    @lits ? "[" . join("", @lits) . "]" : ()
  };
  my %template;
  my $regex = "^";
  for (split //) {
    if (/[a-z]/) {
      $regex .= "$_";
    } elsif (/[A-Z]/) {
      if (exists $template{$_}) {
        $regex .= $template{$_};
      } else {
        my $id = 1 + keys %template;
        if (@avoid) {
          $regex .= "(?!" . join("|", @avoid) . ")";
        }
        $regex .= "(.)";
        push @avoid, $template{$_} = "\\$id";
      }
    } else {
      warn "ignoring $_";
    }
  }
  $regex .= "\$";
  print "$_ => $regex\n";
  seek WORDS, 0, 0;
  while (<WORDS>) {
    next unless /$regex/i;
    print;
  }
}

Comment on pat - find words by matching pattern (for crypto)
Download Code
Replies are listed 'Best First'.

Back to Code Catacombs

Log In?
Username:
Password:

What's my password?
Create A New User
Node Status?
node history
Node Type: sourcecode [id://28764]
help
Chatterbox?
and the web crawler heard nothing...

How do I use this? | Other CB clients
Other Users?
Others meditating upon the Monastery: (10)
As of 2015-09-04 11:35 GMT
Sections?
Information?
Find Nodes?
Leftovers?
    Voting Booth?

    My preferred temperature scale is:










    Results (135 votes), past polls