Re: Re: Re: desire to pass file handles by value

[jdporter]

Now if only you could localize a variable that represents the file position, you wouldn't have to manually save/restore its value. Hmmm....

    package Tie::Scalar::FHPos;
    use FileHandle;
    sub TIESCALAR
    {
        my( $pkg, $fh ) = @_;
        bless [$fh], $pkg;
    }
    sub FETCH
    {
        my( $self ) = @_;
        $self->[0]->tell
    }
    sub STORE
    {
        my( $self, $pos ) = @_;
        $self->[0]->seek($pos,0);
    }

Test:

open F, "< foo.dat";
our $pos;
tie $pos, 'Tie::Scalar::FHPos', \*F;

{
 local $pos = 20;
 print "$pos: ", scalar(<F>);
}
print "$pos: ", scalar(<F>);

Cool!

[ysth]

Nice. It does have negative one side effect, though. If you are reading from some other file (say <STDIN>), and you reference $pos, the tell or seek will change perl's idea of the most recent input file to F. This will mess up the "<STDIN> line n" in any error/warning message, and also change what handle the $. var is looked up in.

To fix this, put a local $.; in STORE and FETCH. (For some reason, this then triggers some warnings from STORE when $pos is localized. Fix by saying seek($pos||0,0)).

[jdporter]

Ah, thanks for debugging that. When I tried it on STDIN, I got the fubar, and simply dismissed it with a "What do you expect, seeking back and forth on a non-file stream?" :-)
But Perl is smarter than I am... as usual.