You can force print to fail by selecting a filehandle that you know is unwritable. Here's a quick-n-dirty little module that returns a tied filehandle that fails when written to:

package NoPrint;
use Symbol;

sub new {
    my $sym = gensym;
    tie *$sym, $_[0];
    bless $sym, $_[0];
}
sub TIEHANDLE { bless {}, $_[0] }
sub PRINT { return undef }
sub PRINTF { return undef }
sub WRITE { return undef }
[download]

You can now use it like this:

my $old_fh = select NoPrint->new;

## deep inside some test somewhere...
print "foo\n" or warn "print failed (1)";

select $old_fh;

## now printing is back to normal again:
print "foo\n" or warn "print failed (2)";
[download]

Update: An alternative that might even be is much cleaner is to localize *STDOUT:

{
    local *STDOUT = NoPrint->new;
    print "foo\n" or warn "print failed (1)";
}

print "foo\n" or warn "print failed (2)";
[download]

---

---

• Are you posting in the right place? Check out Where do I post X? to know for sure.
• Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:

  <code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>

• Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
• Want more info? How to link or How to display code and escape characters are good places to start.