use strict;
use warnings;

use PerlMonks::Mechanized;

my $timeformat = '%Y-%m-%d %H:%M:%S'; # format for strftime

# should put username and password into ENV vars instead
my $pm_obj = PerlMonks::Mechanized->new( 'username', 'passwd' );

#***********************************************************

my @msgs;

my $since_id = 0;   # get all messages
my $delay    = 10;  # num secs between page requests (init value)
my $max_recs = 100; # max # records to return at a time (init value)

while( 1 )
{
    my ( $data, $info ) = $pm_obj->private_message(
                                         archived => 'both',

                                         xmlstyle => 'clean',
                                         since_id => $since_id,
                                         max_recs => $max_recs,
                                         min_poll_seconds => $delay );

    last if( not defined $data );

    # update the max_recs and min_poll_seconds params
    # based on the values in INFO
    $delay    = $info->[0]->{min_poll_seconds} || $delay;
    $max_recs = $info->[0]->{max_recs} || $max_recs;

    # save the msgs for processing (could just print now instead)
    push( @msgs, @{ $data } );

    # msgs are returned in ascending id order, so the
    # last msg is the most recent
    $since_id = $data->[-1]->{message_id};

    print 'retrieved ', scalar @{ $data }, ' messages';

    if( scalar @{ $data } <= $max_recs )
    {
        print "\n";
        last;
    }

    print ", sleeping $delay secs\n";
    sleep( $delay );
}

print "\nprivate messages:\n";

foreach my $msg ( @msgs )
{
    my $datetime = format_datetime_string( $msg->{time},
                                           $timeformat );
    print "$datetime - $msg->{author}: $msg->{content}\n\n";
}

#***********************************************************

sub format_datetime_string
{
    my ( $string, $format ) = @_;

    # $string is of the format: YYYYMMDDhhmmss

    # YYYY = 4 digit year
    # MM = month, 1-12
    # DD = day, 1-31
    # hh = hour (24 hr scale, EST)
    # mm = min
    # ss = sec

    my $year  = substr( $string, 0,  4 );
    my $month = substr( $string, 4,  2 );
    my $day   = substr( $string, 6,  2 );
    my $hour  = substr( $string, 8,  2 );
    my $min   = substr( $string, 10, 2 );
    my $sec   = substr( $string, 12, 2 );

    # strftime expects $month to be 0..11 and
    # $year to be num yrs since 1900
    return POSIX::strftime( $format, $sec, $min, $hour,
                            $day, $month-1, $year-1900 );
}