Re: MAC Address of An Interface

Did you say SNMP?

Or, if you want to get the MAC addresses of a whole bunch of devices at once (including any IP aliases that might be set up), you can do:

# DO NOT USE THIS WITHOUT YOUR NET ADMINS' PERMISSION!
# YOU PROBABLY WON'T HURT ANYTHING, BUT YOU'LL UPSET THEM
# IF YOU DON'T ASK FIRST.
use SNMP; # Requires Net-SNMP package from SourceForge.
use strict;

my $community;
my $defgate;
my $mib;
my $sess;
my $var;
my $vb;

my %ARP;
my %sessparms;

# Initialize SNMP.
$SNMP::use_sprint_value = 1;
# The MIB objects we need are pre-loaded in Net-SNMP.
&SNMP::initMib();

$community = 'public';  # Use your read-only community here.
$defgate = '127.0.0.1'; # Use your default gateway here.
$sessparms{'DestHost'} = $defgate;
$sessparms{'Community'} = $community;
$sessparms{'Version'} = '2'; # Recommended.

$sess = new SNMP::Session(%sessparms);
if ( not defined $sess ) {
  die "Couldn't open SNMP session to $defgate.\n";
}

$mib = 'ipNetToMediaPhysAddress'; # ARP table.
$vb = new SNMP::Varbind([$mib]);
GETARP: while ( $vb->tag eq $mib ) {
  $var = $sess->getnext($vb);
  if ( $sess->{ErrorNum} ) {
    print "Got $sess->{ErrorStr} querying ARP table on $defgate.\n";
    last GETARP;
  }
  if ( $vb->iid =~ /(\d+\.\d+\.\d+\.\d+)$/ ) {
    $ARP{$1} = $var;
  }
}

# Not the best sort for this, but hey...
foreach ( sort keys %ARP ) {
  print sprintf "MAC for %-15s is %17s.\n", $_, $ARP{$_};
}
[download]

NOTES:

As it says, this is unwise to do if you don't have the permission of whoever is running the router. You'll set off all sorts of security alarms, the DoHS will drag you away and you'll never be heard from again. {:-O
If you have a bunch of machines running this script against the same router at the same time, you can bog down its CPU (although I've never seen a single querier create such a problem, and most routers set management traffic to a low priority anyway).
The format of the instance numbers ($vb->iid) changes from router to router, so you may want to add a print "IID is ", $vb->iid, "\n"; in there to see for yourself if things aren't working.

Enjoy!

--J

Update: Gave a shorter while loop with a better test. Fixed arg to SNMP::Session() (a hash, not a hashref). Added test for successful session creation.

Update: Added proper 'header' line to fit the rest of the thread. ;-)

Comment on Re: MAC Address of An Interface Select or Download Code


Welcome to the Monastery
	PerlMonks