return multiple hashes from a sub

[rsiedl]

Hi Monks,

Can anyone tell me if it's possible/and how to return multiple hashes from a sub routine?
Something like below (this isnt working):

#!/usr/bin/perl

use strict;

my (%hash1, %hash2) = &build_hashes;

foreach (keys (%hash1)) {
  print $_, ":", $hash1{$_}, "\n";
} # end-foreach

foreach (keys (%hash2)) {
  print $_, ":", $hash2{$_}, "\n";
} # end-foreach


sub build_hashes {
  my %hash1 = { 1=>"foo1", 2=>"bar1" };
  my %hash2 = { 3=>"foo2", 4=>"bar2" };
  return (\%hash1, \%hash2);
} # end-sub
exit;

Cheers,
Reagen

[monkey_boy]

You need to read about references,
but heres the answer ...


my ($hash1, $hash2) = &build_hashes;

foreach (keys (%{$hash1})) {
  print $_, ":", $hash1->{$_}, "\n";
} # end-foreach

foreach (keys (%{$hash2})) {
  print $_, ":", $hash2->{$_}, "\n";
} # end-foreach


sub build_hashes {
  my %hash1 = ( 1=>"foo1", 2=>"bar1" );
  my %hash2 = ( 3=>"foo2", 4=>"bar2" );
  return (\%hash1, \%hash2);
} # end-sub
exit;

[pelagic]

Your initialising was wrong; use:

my %hash1 = ( 1=>"foo1", 2=>"bar1" );
##  instead if
my %hash1 = { 1=>"foo1", 2=>"bar1" };

... no curlies!

[chb]

Try dereferencing the hash references you get from your sub: foreach (keys %$hash1) { ... }.

[aquarium]

The modular approach calls for a build_hash sub, which gets called with parameters (twice) to build each hash, and return a reference to that. if you programmed this in OO style, it would be similar to the modular -- divide and conquer -- approach. The other way is to return a reference to an anonymous hash/array of hashes. just a little different to dereference then.