#!/usr/bin/perl

use strict;
use warnings;

$/ = '>';   # read up to the end of one tag at a time

my $lineno = 0;
my @tagstack;

while (<>) 
{
    $lineno += tr/\n//;
    unless ( />$/ ) {  # must be at eof;
        print;
        next;
    }

    my ( $pre, $tag ) = ( /([^<]*)(<[^>]+?)>/ );

    if ( !defined( $tag )) {
        warn "'>' without prior '<' at or near line $lineno\n";
        print;
    }
    elsif ( $tag =~ m{^</} ) { # close tag: look for its open tag on the stack
        unless ( @tagstack ) {
            warn "extra close tag '$tag' at or near line $lineno\n";
            print;
            next;
        }
        $tag = substr $tag, 2;
        my $stackindx = $#tagstack;
        while ( $stackindx >= 0 and $tagstack[$stackindx] ne $tag ) {
            $stackindx--;
        }
        if ( $stackindx < 0 ) {
            warn "close tag '$tag' lacks open tag at or near line $lineno\n";
            print;
            next;
        }
        print $pre;
        if ( $stackindx != $#tagstack ) {  # add close tags as needed
            while ( $stackindx < $#tagstack ) {
                warn "added '</$tagstack[$#tagstack]>' at line $lineno\n";
                printf "</%s>\n", pop @tagstack;
                $lineno++;
            }
        }
        print "</$tag>";
        pop @tagstack;
    }
    elsif ( $tag =~ m{^<!} or $tag =~ m{/$} ) {  # "comment" or empty tag
        print;
    }
    else {  # this must be an open tag -- push it on the stack
        $tag =~ s/<(\S+).*/$1/s;
        push @tagstack, $tag;
        print;
    }
}