Getting a base name

[Anonymous Monk]

Master,
Why this code:

perl -e '
$fname = 'test.txt'; 
$base = (split(/./,$fname))[0]; 
print "$base\n";'

Doesn't prints me:

test

Thanks a million again.

[Iron]

You should use

$base = (split(/\./,$fname))[0];

and better solution is File::Basename

[reasonablekeith]

It’s not immediately apparent how you would use it though (File::Basename).

See Re: Parse out the extension of a filename - return base of filename. for an example which copes with no dots and multiples dots in a file name (something which none of these examples do)

[Smylers]

Put a backslash before the dot.

Smylers

[Zaxo]

Iron wisely suggests File::Basename. Here's how it goes,

use File::Basename;
my $filename = "../../path/to/test.txt";
my $basename = basename( $filename, '.txt', '.dat');
print $basename, $/;

__END__
test

If you omit the extension list arguments, or if $filename's extension is not in the list, basename() will return the basename with extension.

F::B also offers the functions dirname(), which extracts just the directory part, and fileparse(), which returns a list of ($basename, $dirname, $extension)

[polettix]

You're using single quotes inside single quotes; moreover, the dot is a special character in a regexp, you have to escape it:

perl -e '
$fname = "test.txt";              # Double quotes! 
$base = (split(/\./,$fname))[0];  # Escape dot!
print "$base\n";'

[Tanalis]

You need to escape the '.' in your split:

$base = ( split(/\./,$fname) )[0];

Adding -Mstrict and -w (always a good idea), the following works fine for me:

perl -Mstrict -w -e '
  my $fname = "test.txt";
  my $base  = ( split(/\./,$fname) )[0];
  print "$base\n";'

Update: And, as others have mentioned, you have single quotes inside single quotes, too :)

Hope that helps ..

[gube]

$fname = 'test.txt'; 
$base = (split/\./, $fname)[0]; 
print "$base\n";

[reasonablekeith]

Your dot is matching anything, you wanted to match a dot explicitly

$base = (split(/\./,$fname))[0];

UPDATE: Too slow, that's probably enough replies now :-)

[anonymized user 468275]

The delimiter for split is being parsed locally as a regular expression wildcard which is not very useful in this context. Either escaping it with backslash /\./ or enclosing in single quotes '.' will do the trick, although the latter will be more difficult in this case given that the whole program is also enclosed in single quotes.