note
Hofmator
Well, another command-line-parsing-module ... but I must say, I prefer [module://Getopt::Long] which is a core module and therefore available everywhere. In addition to that, there are plenty of tests for [module://Getopt::Long], it is more flexible and easier to use (eg. no need to define subs that match the arguments by hand). Apart from that, your module has a couple of problems, eg. it doesn't need Exporter, has a inconsistent interface (why can I say <c>my @singles = $a->getSingles;</c> but not <c>my %keyvals = $a->getKeys</c>), ...
<p>To underline my point, I have rewritten the script given in your POD using [module://Getopt::Long]. The only difference is that '-4Adam;Barbara' is now written as two arguments -4 and 'Adam;Barbara'. Btw, your script as given doesn't compile, it uses croak without <c>use Carp;</c> - I have replaced that with a simple <c>warn</c>.
<c>use strict;
use warnings;
use Getopt::Long;
my $usage_msg = <<'EOHELP';
greeter is a sample program for Argdom.pm.
--help | -h displays this help message and quits.
-o outfile is the file to which the output is written. Can be many, as in -o f1 -o f2 -o f3. `-' means the STDOUT (default).
-xclaim means the output should be exclamatory.
-4 X;Y;Z means the greeting should be for X, Y, and Z. Default is ``World'' and yourself!.
any other args are the greeting. Default is "Hello"./;
EOHELP
my $xclaim = 0;
my $usage = 0;
my $greeting = '';
my $forWhom = 'World;to you';
my @outs;
GetOptions ("h|help" => \$usage,
"xclaim!" => \$xclaim,
"4=s" => \$forWhom,
"o=s" => \@outs,
) or die $usage_msg;
if ($usage) {
print $usage_msg;
exit;
}
$greeting .= $_ foreach @ARGV;
$greeting = 'Hello' unless $greeting;
@outs = qw/-/ unless @outs;
my $output = '';
$output .= "$greeting, $_" . ($xclaim ? '!' : '.') . "\n"
for (split /;/, $forWhom);
foreach my $outfile (@outs) {
if ($outfile eq '-') {
print $output;
} else {
open my $outfh, '>', $outfile or warn "Could not open $outfile for writing: $!";
print $outfh $output;
close $outfh;
}
}
</c><!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-85506">
<P>-- Hofmator</P>
<p><small><i>Code written by Hofmator and posted on PerlMonks is public domain. It is provided as is with no warranties, express or implied, of any kind. Posted code may not have been tested. Use of posted code is at your own risk.</i></small></p>
</div></div>
583302
583302