Re^2: Tk and ImageMagick

[zentara]

You can use Image::Magick and Tk together without any problem. The thing to remember, is what each module does best, and how they interact. Tk is basically just a display engine. The Tk::Photo module has some very crude image manipulation methods, but IM has some great ones. So you use IM to do your manipulations, and Tk to do your input and display. The way to connect the two, is through in-memory files. Tk::Photo does this with the -data option, and IM uses the 'blob'. One other thing to remember, is that the Tk -data option wants it as base64 encoded strings. So you will need to have some subs to convert base64 back and forth. You really have to watch out for Tk leaking memory through left over Photo objects, so you need to reuse Photo objects. Here is a simple example that views all jpg, png, and gif's in a dir, with IM manipulation.

#!/usr/bin/perl -w
use strict;
use Tk;
use Tk::JPEG;
use Tk::PNG;
use Image::Magick;
use MIME::Base64;

my $val = 0;
my $im = Image::Magick->new; # a single object for thumbnails
my $c;
my $dir = ".";
my @fl = <*.jpg *.png *.gif>;
print "@fl\n";

my $main = new MainWindow;

my $photo_obj = $main->Photo(-file => '' );

my $display = $main->Label(-width => 200, 
                           -height => 200,
               -image => $photo_obj,
              )->pack(-fill=>'both', -expand=>1); 

&loadpic( $fl[0] );

my $frame = $main->Frame()->pack();

my $nxt = $frame->Button(-text  => "Next", 
            -command => \&nextp)->pack(-side=>'left');

$frame->Button(-text => 'exit',
              -command => sub{destroy $main}
              )->pack(-side=> 'left');


$frame->Checkbutton(
                -onvalue => 1,
                -offvalue => 0,
        -text => 'Charcoal',
                -variable => \$val)->pack(-side=> 'left');


$main->bind("<Visibility>", sub { $nxt->invoke });

MainLoop;


sub loadpic {
    my $filename = shift;

    $photo_obj->blank; #clear out old jpg

    my ($h,$w) = ($display->height, $display->width);
    #
# how to scale the pic?
   # Create new size version
   $im->Read($filename);
   $im->Scale( geometry => $w.'x'.$h );
   
   if($val){ $im->Charcoal('0x1') }
   
   
   #Tk needs base64 encoded image files
   my $data = encode_base64( $im->ImageToBlob() );
   undef @$im; # blank $im object 

   $photo_obj->put($data); 
   $display->configure(-image => $photo_obj);

}

sub nextp {
    push (@fl,shift(@fl)); #circular list

    my $f = $fl[0];
    loadpic("$dir/$f");
}