Parsing a data file to find the highest value.

[misconfiguration]

Hello Monks,

Long time reader first time poster.

I'm currently writing some code to better automate adding a print queue on HP-UX and AIX systems. These printers are addressed by a simple numeric identifier, each has to be unique. I'm wanting to have Perl read the text file and figure out which is the highest number, then store it in a Scalar for later use in the script.

Any input that points me in the right direction is greatly appreciated.

[FunkyMonk]

As moritz has said, without seeing the format of the input file it's impossible to give a definitive answer, but the following may help you get started

update: Changed the regex to match the data provided by the OP.

my $high_id = 0;
open my $ID_FILE, "<", "path/to/file" or die $!;
while ( <$ID_FILE> ) {
    my ( $id ) = m/:(\d+):/; # extract first number from line
    $high_id = $id if $id > $high_id;
}
print "highest id found = $high_id\n";

[misconfiguration]

Sorry for the lack of information guys, I'll show you the basic syntax of our printer config file.

M08_amvpss09_MEDIP :279:lp -damvpss09 >amvpss09.trace 2>&1

The number :279 is the identifier we need to locate and add by one.

There are over 700 unique numbers in no particular order, Are you guessing that this will need to be sorted by columns?

[tcf03]

Depending on the file format, perhaps something like this?

#!/usr/bin/perl

use strict;
use warnings;

my %prns;

for (<DATA>)
{
    my ( $num, $prn ) = split /\s/;
    $prns{$num} = $prn;
}

my @ord = sort { $b <=> $a } keys %prns;

print "Highest numbered printer is $prns{shift @ord}\n";

__DATA__
1 prt1
2 prt2
99 prt99
10 prt10
100 prt100
7 prt7

update


use strict;
use warnings;

my %prns;

for (<DATA>)
{
    my ( $printer, $num, $cmd ) = split /:/;
    $prns{$num} = $printer;
}

my @ord = sort { $b <=> $a } keys %prns;

print "Highest numbered printer is $prns{shift @ord}\n";

__DATA__
M08_amvpss09_MEDIP :275:lp -damvpss09
M07_amvpss09_MEDIP :279:lp -damvpss09
M09_amvpss09_MEDIP :278:lp -damvpss09
M01_amvpss09_MEDIP :2:lp -damvpss09
M04_amvpss09_MEDIP :1000:lp -damvpss09

[fenLisesi]

Why would you do a full sort just to find the maximum value?

[tcf03]

Its just what I though of first. You could also do:

use strict;
use warnings;
use List::Util qw(max);

my %prns;

while (<DATA>)
{
    my ( $printer, $num, $cmd ) = split /:/;
    $prns{$num} = $printer;
}

print "Highest numbered printer is $prns{max (keys %prns) }\n";
__DATA__
M08_amvpss09_MEDIP :275:lp -damvpss09
M07_amvpss09_MEDIP :279:lp -damvpss09
M09_amvpss09_MEDIP :278:lp -damvpss09
M01_amvpss09_MEDIP :2:lp -damvpss09
M04_amvpss09_MEDIP :1000:lp -damvpss09

Something line FunkyMonk's suggestion would work as well.

[moritz]

The first step is to parse these files, and we can't help you with that unless we know what they look like.

So the first step is to provide a sample config file here ;)

[sh1tn]

perl -ne '$"<($_=(split(/:/, $_))[1]) and $"=$_;eof&&print$"' file.con
+f

[Himalaya]

Its a great command line usage. But it does NOT work if input data is negative numbers. Can you throw some light? -Thanks