Re: Replacing string with regexp without using modules

[pc88mxer]

in reply to Replacing string with regexp without using modules

For your first question:

sub prog_replace_string {
  my ($replace_this, $with_this, $string) = @_;
  $string =~ s{\Q$replace_this\E}{$with_this}g;
  $string;
}

For your second:

sub replace_vars {
  my ($string, $hash) = @_;
  $string =~ s{\$(\w+)}{$$hash{$1}}ge;
  $string;
}

my %vars = ( a => 1, b => 22, c => 333 );
print replace_vars('a: $a, b: $b, c: $c', \%vars);

[cowgirl]

Thanks for the great reply. It works well. However when I cut it down to this, it doesn't work:

  $string = '$a $b $c';
  $hash{a} = "go";
  $string =~ s{\$(\w+)}{$$hash{$1}}ge;

Could it be the hash reference you use to the subroutine? \$hash ? Thanks.

[almut]

Could it be the hash reference ...?

Yes, in pc88mxer's code, $hash is a hash reference, so it must be dereferenced. In your case, it's a normal hash.  So either don't dereference

$hash{a} = "go";
$string =~ s{\$(\w+)}{$hash{$1}}ge;

or create a reference

$hash->{a} = "go";
$string =~ s{\$(\w+)}{$$hash{$1}}ge;

or even use the normal arrow syntax in both the assignment $hash->{a} = ..., and when you access it $hash->{$1}:

$hash->{a} = "go";
$string =~ s{\$(\w+)}{$hash->{$1}}ge;