Re: How do I put bracket on substring(s) of a string?

[Roy Johnson]

#!perl
use strict;
use warnings;


my @testdata = (['CCCATCTGTCCTTATTTGCTG', [qw(ATCTG ATTTG)]]
               ,['ACCCATCTGTCCTTGGCCAT',  [qw(CCATC)]]
               ,['CCACCAGCACCTGTC',       [qw(CCACC CCAGC GCACC)]]
               ,['CCCAACACCTGCTGCCT',     [qw(CCAAC ACACC)]]);

for (@testdata) {
  my ($str, $pats) = @$_;
  print put_bracket($str, @$pats), "\n";
}

sub put_bracket
{
    my $str = shift;
    # Combine multiple match strings into alternations
    my $rx = join '|', @_;
    my @brackets;
    # Store bracket points for every match
    while ($str =~ /(?=($rx))/g) {
      push(@brackets, [$-[0], length($1)+$-[0]]);
    }
    # Condense overlapping brackets
    for my $i (0..$#brackets-1) {
      if ($brackets[$i][1] >= $brackets[$i+1][0]) {
        $brackets[$i+1][0] = $brackets[$i][0];
        @{$brackets[$i]} = ();
      }
    }
    # Apply the brackets (from back to front)
    while (@brackets) {
      my $b = pop @brackets;
      next unless @$b;
      substr($str, $b->[1], 0) = ']';
      substr($str, $b->[0], 0) = '[';
    }
    return $str;
}