return Both ARRAY and SCALAR

[FutureBoyNil]

Good day honorable monks. I humbly come to these gates seeking enlightment. I want a function to return a variable with both SCALAR and ARRAY values. It works for regular functions:

sub XX{
	my $x = 'one'; #scalar value
	push(@{$x}, 'two'); #overload array
	push(@{$x}, 'three'); #overload array
	return $x;
}

my $y = XX(); # typecastable scalar!
print join(", ",$y, @{$y}); # prints "one, two, three"

But as soon as I make it a module, this behaviour dissapears! so:

use MYMOD;
my $x = MYMOD->new();

my $y = $x->XX(); # $y is SCALAR only...

The reason is that I wrote a standalone data parser, and, just like xml, a tag can have multiple ocurrences, thus it is not guaranteed to be unique, but it could be. For now I use get_value() and get_values().

[jhourcle]

You wouldn't have gotten that behaviour if you had 'use strict'.

You're not actually overloading, what's happening is that you're assigning to an array based on the name of the variable:

sub XX{
    my $x = 'one'; #scalar value
    push(@{$x}, 'two'); #  push(@one, 'two')
    push(@{$x}, 'three'); # push(@one, 'three')
    return $x;
}

Once it's in a module, '@one' is out of scope. If you really want this exact behaviour, you're likely going to need to look into a tied array that stringifies to your 'scalar' value.

[almut]

I want a function to return a variable with both SCALAR and ARRAY values.

Couldn't you use wantarray to make the method return either a single value (in scalar context) or more values (in list context)?

[JavaFan]

use 5.010;

use strict;
use warnings;

package Foo;

use overload
   '""'   =>  sub {${$_[0]}{SCALAR}},
   '@{}'  =>  sub {${$_[0]}{ARRAY}}
;


sub XX {
    bless {SCALAR => 'one', ARRAY  => ['two', 'three']}, shift;
}


package main;

my $y = Foo->XX;  
say join ", ", $y, @$y;


__END__
one, two, three

[FutureBoyNil]

This is exactly what I was looking for. Thank you very much!

[Mutant]

Instead of doing what you're doing, you could just store everything in an array. Then for fields you know have only one value, just do:

my ($field) = $parser->get_values();

Not perfect, but probably cleaner than the approach you're trying to take. (Whether it's useful or not will depend on exactly how you're using this data, which you haven't explained).