Extracting text from a line

[kirkbrown]

Given a string of text like: UID: dlsmith3

How would I extract "dlsmith3" and print it to a separate file?

I want to avoid extracting strings from strings like Supervisor UID: plbaerr4

[almut]

my ($uid) = $string =~ /^UID: (\w+)/;
print $fh $uid if $uid;

(where $fh is a file handle opened for writing to the other file)

[targetsmart]

print $fh $uid if $uid;

you meant to say
print $fh $1 if $uid;
I guess.

update almut was right
I thought it was scalar context, missed to notice that "(" ")" => "list context" ,my mistake :-).
Thanks to almut and pemungkah

[almut]

What's the difference, semantically?

Note that in list context (my ($uid) = ...), the match operation returns the captures, so $uid holds the same value as $1.  If there is no match, both values are undef.

[ww]

Or

#!usr/bin/perl
use strict; 
use warnings; 
# 848903

my @strings = ("Supervisor UID: plbaerr4",
                "UID: dlsmith3",
                "Peon UID: jklmn2");

for my $string(@strings) {
    if ( $string !~ /^Supervisor \w+/ && $string =~ /UID: (\w+)/ ) {
        print "$1 \n";
    } else {
        print "No match in $string \n";
    }
}

almut's reply handles the file-writing spec; this addresses ambiguity in OP's spec: is it the "Supervisor" UID that's verbotten or any UID preceded by a title?

Updated: preceding para dropped from cut and thus not pasted. Duh.

[nvivek]

You try this.It is similar to almut's answer but we don't know whether there will be space between UID: and string.Following will solve that problem and it works.

#!usr/bin/perl
use strict; 
use warnings; 

my @input = ("Supervisor UID: plbaerr4",
                "UID:dlsmith3",
                "Peon UID: jklmn2");

open FH,">output.txt" or die "can't open file for writing:$!";

for my $string (@input) {

print FH  $1 if($string=~/^UID:\s*(\w+)/);

}

close FH;

[suhailck]

In Unix/Linux,



perl -ne 'print $1 if /^UID:\s*(\w+)/' fileRead  > fileWrite



~suhail