Scaler found where opeartor expected Error

[mipatel]

hello, i am having trouble debugging this program could someone help me please

foreach $Author2 ( @author_order ) { 
     $auth  = $author_books{ $Author2 };
    my $books = $auth->{order}; 
    push @body, "<tr><td rowspan="${\scalar, @$books}"$Author2</td>\n"
+;
    my $line = 0;
    foreach my $book ( @$books ) { 
        push @body, '<tr><td></td>' if ++$line;
        push @body
           , ( "<td>$book</td><td>"
             . join( "<br/>\n", @{ $auth->{books}{ $book } } )
             . "</td><tr>\n"
             );
    }
}

The error says Scalar found where operator expected at rough.pl line 43, near

<tr><td rowspan="$"
        (Missing operator before $?)
String found where operator expected at rough.pl line 43, near "}"$Aut
+hor2</td>\n""
        (Missing operator before "$Author2</td>\n"?)
syntax error at rough.pl line 43, near ""<tr><td rowspan="$"

[muba]

Does it say scaler found, scalar found, or string found?

Let's pick that line apart, though, and see what's happening.

push @body,             # So far so good. We're gonna push something o
+nto the array.
  "<tr><td rowspan="    # Push a string onto the array.
  ${\scalar, @$books}   # What *IS* this, anyway?
  "$Author2</td>\n"     # Another string
;                       # Done. But with what?

Not to mention the missing > in the HTML.

[mipatel]

i am not suppose to use double quotes around the scalar

[NetWallah]

It appears that you are attempting Bash shell style expression evaluation in perl.

Change that to:

 push @body, "<tr><td rowspan='" 
   . scalar( @$books ) 
   . "'>$Author2</td>\n";

[poj]

push @body,"<tr><td rowspan=\"${\scalar @$books}\">$Author2</td>\n";
# add \ \ >                 ^                   ^ ^
# remove ,                             ^

poj

[AnomalousMonk]

This fixes the immediate problem and leaves behind, IMHO, a little nightmare for the poor shlub who has to maintain this code six months or a year from now; better make sure he or she does not know your name or where you live – unless the maintainer is you, in which case justice may be said to have been served! Much better, I think, to use an sprintf statement instead.

>perl -wMstrict -le
"my $books = [ qw(a b c) ];
 my @body = qw(x y);
 my $Author2 = 'defoe';
 ;;
 push @body, qq{<td rowspan=${\scalar @$books}>$Author2</td>};
 push @body, sprintf qq{<td rowspan=%d>$Author2</td>}, scalar @$books;
 print qq{'$_'} for @body;
"
'x'
'y'
'<td rowspan=3>defoe</td>'
'<td rowspan=3>defoe</td>'