Re: Some assistance with splitting variables

[kcott]

This captures the data in the format you want:

$ perl -Mstrict -Mwarnings -E '
    use constant {
        ACTION  => 0,
        FAN_A   => 1,
        FAN_B   => 2,
        SEND    => 3,
        FAILURE => 4,
    };

    my $re = qr{
        \A \d+ \s+ (?<date> \S+ ) .*?
        ACTION=< (?<ACTION> [^>]+ ) > \s+
        FAN_A=< (?<FAN_A> [^>]+ ) > \s+
        FAN_B=< (?<FAN_B> [^>]+ ) > \s+
        SEND=< (?<SEND> [^>]+ ) > \s+
        FAILURE=< (?<FAILURE> [^>]+ )
    }x;

    my $log_line = q{19476 2013-04-05,12:10:51.909293 host:internal.ma
+chine44.company.net main INFO Running normally with ACTION=<processin
+g> FAN_A=<OK> FAN_B=<OK> SEND=<Sent mail (221 2.0.0 Service closing t
+ransmission channel)> FAILURE=<2>};

    $log_line =~ /$re/;
    my ($date, @info) = @+{qw{date ACTION FAN_A FAN_B SEND FAILURE}};

    say $date;
    say $info[ACTION];
    say $info[FAN_A];
    say $info[FAN_B];
    say $info[SEND];
    say $info[FAILURE];
'
2013-04-05,12:10:51.909293
processing
OK
OK
Sent mail (221 2.0.0 Service closing transmission channel)
2

This is just a commandline proof-of-concept. Your real-world application would probably look more like:

...
use constant { ...
my $re = qr{ ...
open my $log_fh, '<', $logfile or die $!;

while my $log_line (<$log_fh>) {
    $log_line =~ /$re/;
    my ($date, @info) = @+{qw{date ACTION FAN_A FAN_B SEND FAILURE}};

    # do something with $date and @info here
}

See perlre - Extended Patterns for details of Named Capture Groups: (?<NAME>pattern)