Push and list context

[uksza]

Hello wise monks,

is any better (more elegant) way to do it:

my @array = qw/one two three/;
my @out;

push @out,"@array\n";
#push @out, reverse @array; <-- "threetwoone"
push @out, "@{[reverse @array]}";

print @out;

thanks for yours wisdom,
Lukasz

[Errto]

I'm not sure whether your main issue is print isn't adding spaces when you print a list, or that what you really want to do is push onto an array a string consisting of another list joined with spaces. If the latter, Mugatu is right. If the former, then you can do either

push @out, reverse @array;
print join " ", @out;

or

push @out, reverse @array;
{ 
   local $, = " ";
   print @out;
}

Update: forgot the reverse

[Mugatu]

If I understand you correctly, this would be the preferred way:

push @out, join " ", reverse @array;

Or, to mimic the example more exactly:

push @out, join $", reverse @array;

[tlm]

It's hard to say what better/more elegant would be in the absence of some context. That said, if all I wanted to do was to print an array forwards and backwards, with spaces between the elements, I'd just do something like

my @array = qw(one two three);
print "@{[@array, reverse @array]}\n";

If you need to keep the reverse array, then

my @yarra = reverse my @array = qw(one two three);
print "@array @yarra\n";

[sh1tn]

my @array = qw/one two three/;

my @out = reverse @array; # or
@out = (@out, reverse @array);

[tphyahoo]

Putting arrays in quotes seems to be the same as joining them. That is, it adds spaces betweeen the elements. This works, and is real easy to read.

use warnings;
use strict;
my @array = qw/one two three/;
my @reversed = reverse @array;
print "@array @reversed", "\n";

[Mugatu]

Putting arrays in quotes seems to be the same as joining them. That is, it adds spaces betweeen the elements.

Array interpolation uses $" as the separator, which defaults to a space, but can be changed to anything. Thus, "@array" is equivalent to join($", @array) (which I had in my earlier reply, but didn't really explain all the way).