#!/bin/perl -w
use strict;

# very simple rules: s="<string>" or v=<number>
my %rules=( 's="toto"' => sub { print "toto!\n";     },
            'v=2'      => sub { print "waouh! 2!\n"; },
          );
# values to test
my @pairs=( toto => 2, toto => 1,  tata => 2,  tutu => 1);

my @rules= make_rules( %rules);                         # create the rules

while (@pairs)
  { my $string= shift @pairs;
    my $value= shift @pairs;
   check_rules( $string, $value);                       # check all rules
   print "\n"; 
}

sub check_rules 
  { my( $string, $value)= @_;
    foreach my $rule (@rules)
      { my( $you_like, $do_it)= @{$rule};
        $do_it->() if( $you_like->( $string, $value));  # run routine if rule applies
      }
  }

sub make_rules
  { my %rules= @_;
    my @rules;
    foreach my $exp (keys %rules)
      { my $sub_str= ' my( $s, $v)= @_;' ;               # get the arguments
        if( $exp=~ m/^s=(".*?")$/)                       # s="<string>"
          { $sub_str .= "return 1 if( \$s eq $1);" ; }   # watch for the \, 
                                                         #    $s is a variable in the sub
                                                         #     while $1 is a variable in make_rules and a constant in the sub
        elsif( $exp=~ m/^v=(\d+)$/)                      # v=<number>
          { $sub_str .= "return 1 if( \$v == $1);" ; }   # watch for the \
        else 
          { die "syntax error in rule $exp"; }
        my $sub= eval "sub { $sub_str }";                # create the anonymous sub
        push @rules, [$sub, $rules{$exp}];               # store it with the sub to run
      }
    return @rules;
  }