#!/usr/bin/perl

use strict;
use warnings;

# Fix Redhat issues with UTF8
$ENV{LC_ALL} = 'en_US';

use Net::Whois::Raw;
use Date::Manip qw(ParseDate UnixDate DateCalc Delta_Format);

# Report domain only if days left is less than
# a given argument.  Default is 60.
my $left;
if (defined $ARGV[0]){
    $left = $ARGV[0];
}else{
    $left = 60;
}

# Add or subtract domains to check from here.
my @domains = qw(
    example.ca
    example.net
    example.org
    );

my ($d, $who, $domain, $expire, %expires, $days, $edate);

format STDOUT_TOP=
     Domains that expire in less than @<<< days
$left
Domain                          Expires      Days Left
------------------------------------------------------
.

format STDOUT=
@<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< @<<<<<<<<<<< @###
$domain, $expire, $days
.

# Calculate days to expiration.

foreach $d (@domains){

    # Lookup domain with whois
    $who = whois($d) or die "Cannot reach whois server";

    # Get expiration date
    if ($who =~ m/expir.*?(\d{2}-\w{3}-\d{4})/i) {
        $edate = $1;

    }elsif ($who =~ m|renewal-date.*?(\d{4}/\d{2}/\d{2})|i) {
        $edate = $1;

    }else{
        $expires{$d} = "Whois failed";
        next;
    }
    # Parse expiration date to yyyy/mm/dd.
    $expires{$d} = dateparse($edate);

}

# Generate report
foreach $d (sort keys %expires){

    $domain = $d;
    $expire = $expires{$d};

    # Do not calculate expired dates if whois failed
    if ($expire eq 'Whois failed') {
        $days = 0;
    }else{
        $days = daystoexpire($expires{$d});
    }

    # Only report if expiration date is earlier than stated.
    if ($days <= $left){
        write STDOUT;
    }
}

# Parse date to yyyy/mm/dd
sub dateparse {
    my $datestr = shift;

    my ($y, $m, $d) = UnixDate($datestr, "%Y", "%m", "%d");
    my $date = "$y/$m/$d";
    return $date;
}

# Calculate days until domain expires
sub daystoexpire {
    my $date = shift;
    
    my $days = DateCalc("today", $date);

    # Format delta date to days.
    $days = Delta_Format($days, 2, '%dh');
    return $days;
}