#!/usr/bin/perl
# GLOBAL - execute a shell command in every subdirectory under cwd
# Stephen Flitman 022408 - inspired by 4NT
# Released under GPLv2

use strict;
use File::Find::Object;
use Getopt::Std;

my %opts;
getopts('hiptvx:',\%opts);

if ($opts{h} or scalar @ARGV<1) {
   print <<"EOT";
Usage:  global [-hitv] [-x pat] 'command' [dir...]
   Execute command in each specified directory plus subdirectories, or the
   current directory and all of its subdirectories.

   -h         This help information.
   -i         Ignore errors.
   -p         Show progress.
   -t         Test mode (does not execute command).
   -v         Verbose (takes precedence over -p).
   -x pat     Exclude all directories matching this shell wildcard pattern.
EOT
   exit(1);
}

my $pat=$opts{x};
$pat=~s/\./\\./g;   # protect dots
$pat=~s/\*/.*/g;    # shell wildcard to regexp match any
$pat=~s/\?/./g;     # shell wildcard to regexp match one char
my $cmd=shift @ARGV;
my $nDirs=0;
my $nErrors=0;
my @dirs=@ARGV;
push @dirs,'.' unless @dirs;
my $tree=File::Find::Object->new({},@dirs);
while (my $dir=$tree->next()) {
   if (-d $dir) {
      next if $pat and $dir!~/$pat/o;
      ++$nDirs;
      if ($opts{v}) {
         printf "%4d. $dir\n",$nDirs;
      }
      elsif ($opts{p}) {
         print "$nDirs\r";
      }
      unless ($opts{t}) {
         my $output=qx/cd "$dir"; $cmd 2>&1/;
         print $output if $opts{v};
         if ($?) {
            printf "$cmd returns error code %d\n",($?>>8) if $opts{v};
            exit 1 unless $opts{i};
            ++$nErrors;
         }
      }
   }
}
printf "Processed %d director%s with %d error%s.\n",$nDirs,$nDirs==1?'y':'ies',$nErrors,$nErrors==1?'':'s';
exit 0;