# For smullis



package Monitor;

use strict;
use IO::Socket::INET;
use vars qw ( @ISA @EXPORT_OK $VERSION );
$VERSION = "0.03";

require Exporter;
@ISA = qw(Exporter);
@EXPORT_OK = qw(
    test_port_simple
    test_port_detailed
);

# testing on port 25 requires sending (your) valid maildomain
my $MAILDOMAIN = 'hotmail.com';

sub test_port_simple {
    my ( $server, $port, $timeout, $verbose ) = @_;
  return "ERR - No server supplied" unless $server;
  return "ERR - No port supplied" unless $port;
    $timeout ||= 10;
    print "Simple testing $server:$port\n" if $verbose;
    my $sock = IO::Socket::INET->new( PeerAddr => $server,
                                      PeerPort => $port,
                                      Proto    => 'tcp',
                                      Timeout  => $timeout,
                                      ReuseAddr=>1,
                                      #ReusePort=>1,
    );
    my $res = $sock ? 'OK' : "ERR - Could not connect socket on port $port";
    $sock->close() if $sock;
    undef $sock;
  return $res;
}

sub test_port_detailed {
    my ( $server, $port, $timeout, $verbose ) = @_;
  return "ERR - No server supplied" unless $server;
  return "ERR - No port supplied" unless $port;
    $timeout ||= 10;
    print "Detail testing $server:$port\n" if $verbose;
    my $sock = IO::Socket::INET->new( PeerAddr => $server,
                                      PeerPort => $port,
                                      Proto    => 'tcp',
                                      Timeout  => $timeout,
                                      ReuseAddr=>1,
                                      #ReusePort=>1,
    );
    unless ( $sock ) {
        undef $sock;
      return "ERR - Could not connect socket on port $port";
    }

    my $errors = '';
    # OK so we have a socket but can we use it as expected
    # depending on the protocol we apply different tests....
    if ( $port == 21 ) {
        my $server = <$sock>;
        if ( $server ) {
            print $sock "USER anonymous\015\012";
            $server = <$sock>;
            $errors .= "No USER response from FTP server\n" unless $server;
            print $sock "QUIT\015\012";
        }
        else {
            $errors .= "No handshake sent from FTP server\n";
        }
    }
    elsif ( $port == 22 ) {
        my $server = <$sock>;
        if ( $server ) {
            # the server expects a string back or logs errors
            # echoing its ID string back shuts up the logs - stealth scan ;-)
            print $sock $server;
        }
        else {
            $errors .= "No handshake sent from SSH server\n";
        }
    }
    elsif ( $port == 25 ) {
        my $server = <$sock>;
        if ( $server ) {
            print $sock "HELO $MAILDOMAIN\015\012";
            $server = <$sock>;
            $errors .= "No HELO response from SMTP server\n" unless $server and $server =~ m/^250/;
            print $sock "QUIT\015\012";
        }
        else {
            $errors .= "No handshake sent from SMTP server\n"
        }
    }
    elsif ( $port == 80 ) {
        print $sock "GET / HTTP/1.0\015\012\015\012";
        my $server = <$sock>;
        $errors .= "Unexpected response from HTTP server: $server\n" unless $server and $server =~ m/^HTTP/;
    }
    elsif ( $port == 110 ) {
        my $server = <$sock>;
        if ( $server ) {
            $errors .= "No OK sent by POP3 server\n" unless $server =~ m/OK/i;
            print $sock "USER nobody\015\012";
            $server = <$sock>;
            print $sock "PASS wrong_password\015\012";
            $server = <$sock>;
            $errors .= "Failed to get expected ERR response\n" unless $server and $server =~ m/ERR/i;
            print $sock "QUIT\015\012";
        }
        else {
            $errors .= "No handshake sent from POP3 server\n";
        }
    }
    elsif ( $port == 3128 ) {
        print $sock "GET http://$server/ HTTP/1.0\015\012\015\012";
        my $server = <$sock>;
        $errors .= "Unexpected response from SQUID PROXY server\n" unless $server and $server =~ m/^HTTP/i;
    }
    else {
        # we don't have a detail test but do have a socket so this is a NOP
    }
    $sock->close();
  return $errors ? "ERR - $errors" : 'OK';
}