# First we'll define this pragma called Regexp::Ascii. This is where
# the magic happens...
#
BEGIN {
	package Regexp::Ascii; $INC{'Regexp/Ascii.pm'} = __FILE__;
	
	use overload ();
	use Carp qw(croak carp);
	
	our %replace = (
		'\d'   => '[0-9]',
		'\D'   => '[^0-9]',
		'\w'   => '[A-Za-z0-9_]',
		'\W'   => '[^A-Za-z0-9_]',
	);
	
	sub import
	{
		shift;
		
		carp "Regexp::Ascii used with no parameters" unless @_;
		
		for (@_)
		{
			croak "Regexp::Ascii does not know what to do with '$_'"
				unless exists $replace{$_};
		}
		
		my $find = join '|',
			map quotemeta,
			sort { length $b <=> length $a or $a cmp $b } @_;
		
		overload::constant 'qr' => sub {
			my $find = 
			(my $re = shift) =~ s/($find)/$replace{$1}/eg;
			return $re;
		}
	}
	
	sub unimport
	{
		overload::remove_constant 'qr';
	}
};

# Here's our test case...
#
use strict;
use warnings;
use Test::More tests => 3;
use constant ARABIC_INDIC_0 => "\x{0660}";

like(ARABIC_INDIC_0, qr/^\d$/, 'unicode');

{
	# use our pragma in this scope
	use Regexp::Ascii qw( \d \D );
	unlike(ARABIC_INDIC_0, qr/^\d$/, 'ascii');
}

like(ARABIC_INDIC_0, qr/^\d$/, 'unicode');