#! perl -slw
use strict;
use List::Util qw[ sum min ];
use Time::HiRes qw[ time ];

sub timeit(&) {
    my $soFar = sum( times() );
    my $start = time;
    $_[0]->();
    return sprintf "Wall:%6.3f secs; cpu:%6.3f secs",
        time() - $start, sum( times() ) - $soFar;
}

our $T //= 10e6;
our $N //= 10;
our $B //= 10;

my @data = map{ sprintf "%4.2f", rand() } 1 .. 10e6;

print 'Add 1   and sort; add 1   and sort ...: ', timeit {
    my @top = sort{ $b <=> $a } @data[ 0 .. $N-1 ];

    for( my $i = $N; $i < $T; ++$i ) {
        @top = ( sort{ $b <=> $a } @top, $data[ $i ] )[ 0 .. $N-1 ];
    }
#    print "@top";
};

print "Add $B and sort; add $B and sort ...: ", timeit{
    my @top = sort{ $b <=> $a } @data[ 0 .. $N-1 ];

    for( my $i = $N; $i < $T; $i += $B ) {
        @top = sort{ $b <=> $a } @top, @data[ $i .. min( $i+$B, $#data ) ];
        $#top = $N;
    }
#    print "@top";
};

__END__
C:\test>1052498-3 -T=10e6 -B=1e1
Add 1   and sort; add 1   and sort ...: Wall:89.400528 secs; cpu:89.047000 secs
Add 1e1 and sort; add 1e1 and sort ...: Wall:18.483192 secs; cpu:18.391000 secs

C:\test>1052498-3 -T=10e6 -B=1e2
Add 1   and sort; add 1   and sort ...: Wall:87.353784 secs; cpu:86.438000 secs
Add 1e2 and sort; add 1e2 and sort ...: Wall:9.385142 secs; cpu:9.234000 secs

C:\test>1052498-3 -T=10e6 -B=2e2
Add 1   and sort; add 1   and sort ...: Wall:87.380 secs; cpu:87.046 secs
Add 2e2 and sort; add 2e2 and sort ...: Wall: 9.135 secs; cpu: 9.156 secs

C:\test>1052498-3 -T=10e6 -B=1e3
Add 1   and sort; add 1   and sort ...: Wall:87.436786 secs; cpu:86.625000 secs
Add 1e3 and sort; add 1e3 and sort ...: Wall:9.377329 secs; cpu:9.329000 secs

C:\test>1052498-3 -T=10e6 -B=1e4
Add 1   and sort; add 1   and sort ...: Wall:87.435 secs; cpu:86.298 secs
Add 1e4 and sort; add 1e4 and sort ...: Wall:10.077 secs; cpu: 9.843 secs