#!/usr/bin/perl
#
use strict;
use warnings;

$ARGV[0] or die "Usage: $0 <filename> [<filename>] ...";

my ( $template_file_name, $templateText, %hash ) = '';
my @vars = split "\n", <<END;
##location##
##rtrname##
##loop0-ip##
##frame-ip##
##frame-DLCI##
##eth0-ip##
END

while (<>) {
	chomp;
	my @fields     = split /,/;
	my $templateFN = pop @fields;

	if ( $template_file_name ne $templateFN ) {
		$template_file_name = $templateFN;
		undef $templateText;
	}

	@hash{@vars} = @fields;

	$templateText //= getTemplateText($template_file_name);
	my $templateTextCopy = $templateText;

	$templateTextCopy =~ s/$_/$hash{$_}/g for keys %hash;

	my $ofile_name = $hash{'##rtrname##'} . '.txt';

	open my $fh, '>', $ofile_name or die "$ofile_name: $!";
	print $fh $templateTextCopy;
	close $fh;
}

sub getTemplateText {
	my ($template_file_name) = @_;

	local $/;
	open my $fh, '<', $template_file_name or die "$template_file_name: $!";
	$templateText = <$fh>;
	close $fh;

	return $templateText;
}

##</code><code>##

processCSV.pl csv1.csv csv2.csv