Re: find combinations

[Molt]

Okay, the simplest approach here is to get all the combinations (via a convenient CPAN module.. Math::Combinatorics) and then filter those for the valid lances. There are almost certainly faster and more efficient ways to do this, but this seems to at least work.

A quick play with the module produced the following code, which at first glance seems to work:

use strict;
use warnings;
use Math::Combinatorics;

my %mechs;

while (<DATA>)
{
    chomp;
    my @d = split /\s+/;
    $mechs{$d[0]} = { weight => $d[1], fraction => $d[2] };
}

# find all lances with 5 members and 380t weight
my @possible_lances = find_lances (3, 150);
for my $lance (@possible_lances) {
  print "Found valid lance:\n";
  my $lance_tonnage = 0;
  for my $mech (@$lance) {
    my $mech_weight = $mechs{$mech}->{weight};
    print "  $mech (${mech_weight}t)\n";
    $lance_tonnage += $mech_weight;
  }
  print "  Total tonnage: ${lance_tonnage}t\n";
}

sub find_lances
{
  my ($count, $max_tonnage) = @_;
  my @valid_lances;
  my $lance_combinations = Math::Combinatorics->new(count => $count, d
+ata => [keys %mechs]);
  while (my @possible_lance = $lance_combinations->next_combination) {
    # Calculate the lance's tonnage
    my $tonnage = 0;
    $tonnage += $mechs{$_}->{weight} for @possible_lance;
    if ($tonnage <= $max_tonnage) {
      push @valid_lances, [@possible_lance];
    }
  }
  return @valid_lances;
}

__DATA__
Flea 20 clan
Commando 25 clan
UrbanMech 30 clan
Hollander 35 clan
Jenner 35 clan
Raven 35 clan
Wolfhound 35 clan
BlackHawk 50 clan
Hunchback 50 clan
Rifleman 60 clan
Catapult 65 clan
Loki 65 clan
Thor 70 clan
MadCat 75  clan
Gargoyle 80 clan
Victor 80 clan
Zeus 80 clan
Longbow 85 clan
Warhawk 85 clan
Mauler 90 clan
Atlas 100 clan

[holli]

I have discovered that module while you were writing the node and came up with the following code (which is similar to yours).

But thanks for your effort.
Read more... (2 kB)