note
Athanasius
<p>Which shows that <tt>sub athanasius</tt> is up to 5 times <i>faster</i> than <tt>sub karlgoethebier</tt>. Even easier to see when supplying a positive <tt>COUNT</tt> value to <tt>timethese</tt>:</p>
<code>
#! perl
use strict;
use warnings;
use Benchmark qw( :hireswallclock cmpthese timethese );
my $string = ".co.uk/Jobs/Company-Sector/C8A6446X4PND86M9WYJ/Tradewind/?APath=2.21.0.0.0";
cmpthese(
timethese
(
1_000_000,
{
'karlgoethebier' =>
sub { $string =~ m/.+\/.+\/.+\/.+\/(.+)\/.+/; return $1; },
'athanasius' =>
sub { return (split '/', $string)[4] },
}
)
);
</code>
<p>Output:</p>
<code>
13:09 >perl 390_SoPW.pl
Benchmark: timing 1000000 iterations of athanasius, karlgoethebier...
athanasius: 5.19894 wallclock secs ( 5.15 usr + 0.00 sys = 5.15 CPU) @ 194250.19/s (n=1000000)
karlgoethebier: 20.2485 wallclock secs (20.08 usr + 0.00 sys = 20.08 CPU) @ 49808.24/s (n=1000000)
Rate karlgoethebier athanasius
karlgoethebier 49808/s -- -74%
athanasius 194250/s 290% --
13:16 >
</code>
<p>Not really surprising, since regexen with quantifiers can be expensive:</p>
<blockquote>
Avoid regular expressions with many quantifiers.... Such patterns can result in exponentially slow backtracking behavior unless the quantified subpatterns match on their first “pass”.
<br />
— <i>The Camel Book</i>, 4<sup>th</sup> Edition, p. 693.
</blockquote>
<p>So, what happens if we limit the backtracking?</p>
<code>
#! perl
use strict;
use warnings;
use Benchmark qw( :hireswallclock cmpthese timethese );
my $string = ".co.uk/Jobs/Company-Sector/C8A6446X4PND86M9WYJ/Tradewind/?APath=2.21.0.0.0";
cmpthese(
timethese
(
1_000_000,
{
'karlgoethebier' =>
sub { $string =~ m/.+\/.+\/.+\/.+\/(.+)\/.+/; return $1; },
'karlgoethebier2' =>
sub { $string =~ m/.+?\/.+?\/.+?\/.+?\/(.+?)\/.+/; return $1; },
'athanasius' =>
sub { return (split '/', $string)[4] },
}
)
);
</code>
<p>Result:</p>
<code>
13:28 >perl 390_SoPW.pl
Benchmark: timing 1000000 iterations of athanasius, karlgoethebier, karlgoethebier2...
athanasius: 4.91799 wallclock secs ( 4.88 usr + 0.00 sys = 4.88 CPU) @ 204792.14/s (n=1000000)
karlgoethebier: 20.1721 wallclock secs (20.05 usr + 0.00 sys = 20.05 CPU) @ 49885.26/s (n=1000000)
karlgoethebier2: 2.55908 wallclock secs ( 2.53 usr + 0.00 sys = 2.53 CPU) @ 395569.62/s (n=1000000)
Rate karlgoethebier athanasius karlgoethebier2
karlgoethebier 49885/s -- -76% -87%
athanasius 204792/s 311% -- -48%
karlgoethebier2 395570/s 693% 93% --
13:29 >perl 390_SoPW.pl
</code>
<p>The regex is now significantly faster than <tt>split</tt>-with-subscript. Interesting!</p>
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-968231">
<p>Athanasius <font color=#008000><°(((><</font> <i>contra mundum</i></p>
</div></div>
1004410
1004437