note
choroba
What does the <c>preprocess</c> sub do? This is my solution without it:<c>
#!/usr/bin/perl
use warnings;
use strict;
use File::Find;
use File::stat;
my $dir = shift;
my %result;
find ( {'wanted' => sub {
my $file = $File::Find::name;
my ($n, $fn) = (getpwuid (stat($file)-> uid))[0, 6];
if (-f && (/^[^.]/) ) {
if( my ($pre, $num, $suff) = $file =~ /(.*)\.([0-9]+)\.(.*)/ ) {
push @{ $result{$pre}{$suff}{"$n:$fn"} }, $num;
}
}
},
},
$dir);
for my $pre (keys %result) {
for my $suff (keys %{ $result{$pre} }) {
for my $user (keys %{ $result{$pre}{$suff} }) {
my @nums = sort { $a <=> $b } @{ $result{$pre}{$suff}{$user} };
my $first = shift @nums;
my ($from, $to, @ranges) = ($first, $first);
for (@nums) {
if ($_ == $to + 1) {
$to = $_;
} else {
push @ranges, [$from, $to];
($from, $to) = ($_, $_);
}
}
push @ranges, [$from, $to];
for my $r (@ranges) {
print "$pre."
. ($r->[0] == $r->[1] ? $r->[0]
: "[$r->[0]-$r->[1]]")
. ".$suff:$user\n";
}
}
}
}
</c>
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-832495">
لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ
</div></div>
1014360
1014360