note
jeffa
Two suggestions: test before you post (and then test some
more) and don't use regexes to parse HTML. Granted, this
is trivial HTML to parse, but the more you use parsers, the
better you get at it. Also, the more you use templating
modules, the better you get at them. I hate to just outright
solve the problem, but i did. Here is link that you will have to click to see my solution - so any readers have
been warned.
<p>
<tt><blink></tt><br/>
<a href="?node_id=280493&displaytype=displaycode">WARNING *SPOILERS* CLICK AT OWN RISK!</a><br/>
<tt></blink></tt>
</p>
<!--
<code>
#!/usr/bin/perl -T
use strict;
use warnings;
use CGI;
use LWP::Simple;
use HTML::Template;
use HTML::TokeParser::Simple;
my $query = CGI->new;
my $template = HTML::Template->new(
filehandle => \*DATA,
associate => $query,
);
my %student = get_students();
my $student = $query->param('student') || '';
if (exists $student{$student}) {
$template->param(%{$student{$student}});
} elsif ($query->param('go')) {
$template->param(error=>"$student does not exist. Try again.",);
}
print $query->header, $template->output;
sub get_students {
my $html = get('http://jamiel.jalme.com/finalgrades.html');
my $parser = HTML::TokeParser::Simple->new(\$html);
my (%student,$token,$name,$grade);
while ($token = $parser->get_token) {
if ($token->is_start_tag('b')) {
$token = $parser->get_token;
$name = $token->as_is;
} elsif ($token->is_end_tag('b')) {
$token = $parser->get_token;
($grade) = $token->as_is =~ /(\d+)$/;
$student{$name} = {
full_name => $name,
grade => $grade,
first_name => (split /\s+/, $name)[0],
}
}
}
return %student;
}
__DATA__
<tmpl_unless full_name>
<html>
<head>
<title>Student Grade Lookup</title>
</head>
<body>
<tmpl_if error><p><tmpl_var error></p></tmpl_if>
<form>
Enter name of student:
<input type="text" name="student" /><br/>
<input type="submit" name="go" value="Enter" />
</form>
</body>
</html>
<tmpl_else>
<html>
<head>
<title>CONGRATULATIONS TO THE PARTICIPANT <tmpl_var first_name></title>
</head>
<body>
<h1><tmpl_var full_name></h1> Has just gotteh a "<tmpl_var grade>" as a
grade for this Seminar. Congratulations!!!<br>
</body>
</html>
</tmpl_unless>
</code>
-->
<p>
It's a lot more code than you posted, but it does a lot
more as well. ;)
</p>
<p>jeffa</p>
<font size=1>
<pre>
L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(<a href="http://jeffa.perlmonk.org/tripdid.mp3">the triplet paradiddle with high-hat</a>)
</pre></font>
280396
280473