note
halley
<p>It took me a bit to get the syntax correct, but there are two special regular-expression features which can be used in combination. <c>(?(condition)yes|no)</c> and <c>(?{code})</c>. The perldoc [perldoc://perlre] page explains that they can be combined, but gives no example. I then use the <c>(?!pattern)</c> construct with no pattern to force a backtrack for each non-word.
<p>Here's my example.
<code>
use strict;
use warnings;
my %vocab = map { $_ => 1 }
qw/one two three four
five six seven eight
nine/;
my $text = "onetwoeightxfour";
my $finder = qr/
(\w+?)
(?(?{ not exists $vocab{$1} })
(?!) | (?=) )
/x;
for ($text =~ m/$finder/g)
{
print $_,$/;
}
</code>
Output:
<code>
one
two
eight
four
</code>
This particular solution is non-greedy: it finds the shortest known word, and leaves the rest for future matches. A more complicated solution would try harder to consume more letters for an early word if it led to fewer un-matched letters in the long-run: "bekindtostewardessesplease" should find 'stewardesses', not 'stew'. Luckily, one possible solution is simple: change <c>(\w+?)</c> to <c>(\w+)</c>, and be patient with the engine as it chugs through the additional backtracking work.
<p>Of course, you can fill the vocabulary hash with whatever you want, or use different code in the <c>(?{code})</c> construct to achieve the solution. You can also replace the <c>(?=)</c> success case to deal with extra unknown letters between words.
<div class="pmsig"><div class="pmsig-249603">
<p>--<br><tt>[ e d @ h a l l e y . c c ]</tt>
</div></div>
491875
491875