note
blokhead
To expand (and generalize) on this a bit, let each type of operation have a precedence. Then as you walk the expression tree, you need to parenthesize operations that have a lower precedence than the expression they appear within.
<p>
A good way to do this is via OO, representing your operation types as subclasses:
<code>
package Op;
sub new {
my $pkg = shift;
bless [@_], $pkg;
}
sub children { @{ $_[0] } }
sub display {
my ($self, $precedence) = @_;
$precedence = 0 if not defined $precedence;
my $s = join $self->op,
map { $_->display($self->precedence) } $self->children;
$s = "($s)" if $precedence > $self->precedence;
return $s;
}
package Op::Addition;
@ISA = qw[Op];
sub precedence { 10 }
sub op { " + " }
package Op::Multiplication;
@ISA = qw[Op];
sub precedence { 20 }
sub op { " * " }
# ...
package Op::Term;
@ISA = qw[Op];
sub precedence { 100 }
sub display { $_[0][0] }
</code>
Then you just call the <tt>display</tt> method on an Op tree. For example,
<code>
Op::Multiplication->new(
Op::Term->new(5),
Op::Addition->new(
Op::Term->new(6),
Op::Term->new(7)
)
)->display;
# 5 * (6 + 7)
Op::Addition->new(
Op::Term->new(5),
Op::Multiplication->new(
Op::Term->new(6),
Op::Term->new(7)
)
)->display;
# 5 + 6 * 7
</code>
And you can see how easy it would be to add new types of operations, due to the beauty of subclassing.
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-137386">
<p>
blokhead
</div></div>
528475
528498