perltutorial
ikegami
<p>I was recently faced with a thread that used <c>.=</c> on a shared variable, and I wondered if that was safe. I figured I'd write up a introductory tutorial on the answer I found. For simplicity, we'll look at <c>++</c> first.
<hr>
<p>The following code outputs 400,000:
<c>
my $count = 100_000;
my $num_calls = 4;
my $sum = 0;
sub inc { ++$sum for 1..$count; }
inc() for 1..$num_calls;
print("$sum\n"); # 400000
</c>
<p>If you ran the 4 calls to <c>inc</c> in parallel, would the answer still be 400,000? Not likely, if you don't change <c>inc</c>.
<c>
use threads;
use threads::shared;
my $count = 100_000;
my $num_calls = 4;
my $sum : shared = 0;
sub inc { ++$sum for 1..$count; }
$_->join for map { threads->create( \&inc ) } 1..$num_calls;
print("$sum\n"); # 314813
</c>
<p>That's because there is a [wp://race condition].
<c>
+=======================+
| CPU |
+-----------+-----------+
| thread 1 | thread 2 |
+===========+===========+
| ... | | T
| load $sum | | i
| inc | | m
+-----------+-----------+ e
| | ... | |
| | load $sum | |
| | inc | v
| | save $sum |
| | ... |
+-----------+-----------+
| save $sum | |
| ... | |
+===========+===========+
</c>
<p>The solution is to protect the [wp://critical section] using a thread synchronization mechanism such as <c>lock</c>.
<c>
use threads;
use threads::shared;
my $count = 100_000;
my $num_calls = 4;
my $sum : shared = 0;
sub inc { for (1..$count) { lock($sum); ++$sum } }
$_->join for map { threads->create( \&inc ) } 1..$num_calls;
print("$sum\n"); # 400000
</c>
<p>Whenever an transformation operation (read ⇒ manipulate ⇒ write) is performed on a shared variable, locking is needed. See [mod://threads::shared] for tools to do this.
<p>The program behind the <c><spoiler></c> below outputs results similar to the following:
<c>
++s sum = 233564 (expecting 400000)
s+=1 sum = 143915 (expecting 400000)
c.=l length = 248149 (expecting 400000)
c=c.l length = 123360 (expecting 400000)
</c>
<p>As you can see, <c>+=</c>, <c>.=</c> and <c>= .</c> are also not atomic. The program can only prove that an operator isn't atomic (i.e. is interruptable). It cannot prove that an operator is atomic (i.e. is not interruptable). If you're getting the "expecting" result, try upping <c>$count</c> and/or <c>$threads</c>.
<spoiler>
<c>
use v5.8.0;
use strict;
use warnings;
use threads;
use threads::shared;
{
my $count = 100_000;
my $threads = 4;
my $sum : shared = 0;
sub inc {
for (1..$count) {
++$sum;
}
}
$_->join
for map { threads->create( \&inc ) }
0..$threads-1;
print("++s sum = $sum (expecting " . ($count*$threads). ")\n");
}
{
my $count = 100_000;
my $threads = 4;
my $sum : shared = 0;
sub inc_assign {
for (1..$count) {
$sum += 1;
}
}
$_->join
for map { threads->create( \&inc_assign ) }
0..$threads-1;
print("s+=1 sum = $sum (expecting " . ($count*$threads). ")\n");
}
{
my $count = 100_000;
my $threads = 4;
my $content : shared = '';
sub append {
my ($letter) = @_;
for (1..$count) {
$content .= $letter;
}
}
$_->join
for map { threads->create( \&append, chr(ord('a')+$_) ) }
0..$threads-1;
print("c.=l length = " . length($content) .
" (expecting " . ($count*$threads). ")\n");
}
{
my $count = 100_000;
my $threads = 4;
my $content : shared = '';
sub concatenate {
my ($letter) = @_;
for (1..$count) {
$content = $content . $letter;
}
}
$_->join
for map { threads->create( \&concatenate, chr(ord('a')+$_) ) }
0..$threads-1;
print("c=c.l length = " . length($content) .
" (expecting " . ($count*$threads). ")\n");
}
</c>
</spoiler>
<p><b>Update</b>: Added the preface and links to Wikipedia.
<p><small>Added to [Tutorials] by [planetscape] <readmore title="view votes">( keep:0 edit:6 reap:0 )</readmore></small></p>