I suppose I need to post my half-solution, too. (My original post was getting long.) It's supposed to replace the rather common looping code:

my $lastid = 0;
while ($sth->fetch) {
    print $row;
    if ($lastid != $id) {
        print "</tr><tr>";
    }
}
[download]

with this:

alternate(
    sub { $sth->fetch },
    sub { print $row },
    sub { $id },              # which variable to monitor
    sub { print "</tr><tr>" } # what to do when variable changes
); 
[download]

Currently it has at least an off-by-one error (the words go into the wrong columns), but I can't spot the error.

sub alternate {
    my $iter = shift;
    my $loop = shift; # main loop callback
    my @conds;
    while (@_ > 0) {
        # sub to get value, sub to call if value changed
        push @conds, [ shift, shift ];
    }

    my @memory;
    return unless $iter->();
    # starting values
    @memory = map { $_->[0]->() } @conds;

    do {
        $loop->();

        while (my ($idx, $cond) = each @conds) {
            my $new = $cond->[0]->();

            next if $memory[$idx] eq $new;

            $cond->[1]->(); # callback

            $memory[$idx] = $new;
            # reset subsequent values
            $memory[$_] = $conds[$_][0]->() for ($idx + 1 .. $#conds);

            last;
        }
    } while ($iter->());
}

my $gen = make_generator(\my ($day, $type, $word));

alternate(
    $gen,
    sub { print "$word, " },
    sub { $day },
    sub { print "</td></tr>\n<tr><td>$day</td><td>" },
    sub { $type },
    sub { print "</td><td>" }
);
[download]

Here is a script which collates the data and produces the desired compact view:

#! perl
use strict;
use warnings;
use feature 'switch';

{
    my %h;
    populate  (\%h);
    stringify (\%h);
    print_view(\%h);
}

sub populate
{
    my ($h) = @_;

    while (<DATA>)
    {
        my ($date, $type, $word) = split /\s+\|\s+/;
        chomp $word;

        unless (exists $h->{$date})
        {
            $h->{$date}{woody_words} = [];
            $h->{$date}{tinny_words} = [];
        }

        given ($type)
        {
            when ('woody') { push @{ $h->{$date}{woody_words} }, $word
+; }
            when ('tinny') { push @{ $h->{$date}{tinny_words} }, $word
+; }
            default        { warn "Datum '$word' of unknown type '$typ
+e'"; }
        }
    }
}

sub stringify
{
    my ($h) = @_;

    for (keys %$h)
    {
        $h->{$_}{woody_str} = join(', ', sort @{ $h->{$_}{woody_words}
+ });
        $h->{$_}{tinny_str} = join(', ', sort @{ $h->{$_}{tinny_words}
+ });
    }
}

sub print_view
{
    my ($h)  = @_;
    my  $max = 0;

    for (keys %$h)
    {
        my $woody_str  = $h->{$_}{woody_str};
        my $new_length = length  $woody_str;
        $max = $new_length if defined $woody_str && $new_length > $max
+;
    }

    printf "   date      | %-*s | tinny words\n", $max, 'woody words';
    printf "-------------+-%s-+-------------\n",  '-' x $max;
    printf "%s  %-*s   %s\n", $_, $max, $h->{$_}{woody_str}, $h->{$_}{
+tinny_str}
        for sort { cmp_dates() } keys %$h;
}

{
    my %months;

    BEGIN
    {
        %months = (Jan =>  1, Feb =>  2, Mar =>  3, Apr =>  4,
                   May =>  5, Jun =>  6, Jul =>  7, Aug =>  8,
                   Sep =>  9, Oct => 10, Nov => 11, Dec => 12);
    }

    sub cmp_dates
    {
        my ($day_a, $mon_a) = $a =~ /^(\d{1,2}) (\w{3})/;
        my ($day_b, $mon_b) = $b =~ /^(\d{1,2}) (\w{3})/;

        return ($months{$mon_a} < $months{$mon_b}) ? -1 :
               ($months{$mon_a} > $months{$mon_b}) ? +1 :
               ($day_a          < $day_b)          ? -1 :
               ($day_a          > $day_b)          ? +1 : 0;
    }
}

__DATA__
28 Sep (Fri) | woody | caribou
28 Sep (Fri) | tinny | litterbin
29 Sep (Sat) | woody | wasp
29 Sep (Sat) | woody | yowling
29 Sep (Sat) | woody | gorn
30 Sep (Sun) | woody | intercourse
30 Sep (Sun) | woody | bound
30 Sep (Sun) | woody | pert
30 Sep (Sun) | tinny | newspaper
01 Oct (Mon) | woody | ocelot
01 Oct (Mon) | woody | concubine
01 Oct (Mon) | tinny | antelope
02 Oct (Tue) | woody | vole
02 Oct (Tue) | woody | sausage
03 Oct (Wed) | tinny | recidivist
03 Oct (Wed) | tinny | tit
[download]

Output:

23:09 >perl 345_SoPW.pl
   date      | woody words              | tinny words
-------------+--------------------------+-------------
28 Sep (Fri)  caribou                    litterbin
29 Sep (Sat)  gorn, wasp, yowling
30 Sep (Sun)  bound, intercourse, pert   newspaper
01 Oct (Mon)  concubine, ocelot          antelope
02 Oct (Tue)  sausage, vole
03 Oct (Wed)                             recidivist, tit

23:10 >
[download]

Of course, the really interesting question is: How do you distinguish words which are ‘woody’ from those which are ‘tinny’?  ;-)

Hope this helps,

Updates: Minor code improvements.

Hmm... looks like I forgot to mention that using the iterator would be nice, rather than slurping it all into a hash. The iterator also guarantees the order (dates in order, woody words before tinny), being from a database and all. Which would have much reduced the sorting need I hope.

Anyway, I've yet to study your code properly, but right now I'm thinking of wrapping my iterator into a second iterator that buffers a day's worth of words. (Dominus's book seems to have had an effect on me.) It's not the nicest answer but one of the easier ones I guess.

Athanasius's solution is the traditional perl solution for the problem you presented. In other words put the data in a hash (to organize the pivot) and then post process the output.

If you are trying to leverage some of the databases functionality as you indicated in your second post then you may want to consider $hash_ref = $sth->fetchall_hashref(); rather than the database sort.

If the goal is to use chapter 4 of Dominus's book to minimize memory overhead then you really just have a recursive problem where you need to identify your base state. (a change of date) You might find the following useful in that case. The data must be pre-sorted by date for this to work. Width formatting is not possible in this output since the data will be printed prior to a test of all rows. That shouldn't be a problem for your suggested goal of web output.

Read more... (2 kB)

TIMTOWTDI!

Update1: changed for to while to honor the iterator concept

Update2: I just noticed I didn't pick up the last line (no base state test when the query ends. (fixed))

Update3: fetchrow_hashref is a better fit and can be used with sort