Here is one way:

#! perl
use strict;
use warnings;
use Date::Calc qw(Days_in_Month Today);

print 'The last day of last month was ', last_day_last_month(), "\n";

sub last_day_last_month
{
    my ($year, $month, $day) = Today([time]);

    if (--$month == 0)
    {
        $month = 12;
        --$year;
    }

    return sprintf("%02d/%d/%d", $month,
                                 Days_in_Month($year, $month),
                                 $year);
}
[download]

Hope that helps,

use Date::Simple qw/today/;
use 5.010;

my $d = today;
my $month = $d->month;
$d-- while $month == $d->month;
say $d;
[download]

Or

use Date::Simple qw/today ymd/;
use 5.010;

my $d = today;
$d = ymd($d->year, $d->month, 1) - 1;
say $d;
[download]

In the spirit of TIMTOWTDI, here's an example using Time::Piece. The advantage of using Time::Piece is that as of Perl 5.10, it's bundled with Perl core. (As is its companion module Time::Seconds.)

use 5.010;
use Time::Piece;
use Time::Seconds qw( ONE_DAY ONE_HOUR );

sub last_day_of_last_month ()
{
    my $now = localtime;
    my $day = Time::Piece->new(
        $now - ($now->day_of_month * ONE_DAY)
    );
    $day += ONE_HOUR * ($now->isdst <=> $day->isdst);
    return $day;
}

say last_day_of_last_month->mdy('/');
[download]

The daylight savings calculation is a bit of an annoyance. :-(

Yeah, that's right; I just did maths with the spaceship operator! :-)

Steps:

1. Find the epoch at 00.00 hrs for Date 1 of current month, current year.

2. Subtract 1 from that to reach previous day and convert that epoch again into date.

3. Grab the date and/or month value from it.

#!/usr/bin/perl -w
use strict;
use Class::Date;

my $date = new Class::Date [`date +%Y`, `date +%m`, 1, 0, 0, 0];

my $curMonthEpoch = $date->epoch;
my $prevMonthEpoch = $curMonthEpoch - 1;

print "Last Date of Prev Month=".`date --date='\@$prevMonthEpoch' +%d`
+;
[download]

use DateTime;

my $one_month_ago = DateTime->today->subtract(months => 1);

print DateTime->last_day_of_month(
    month => $one_month_ago->month,
    year  => $one_month_ago->year,
)->mdy . "\n";'
[download]