Re^3: How to get at perl's options in a program

[kennethk]

in reply to Re^2: How to get at perl's options in a program
in thread How to get at perl's options in a program

A fairly reliable way to test if a module was loaded is to check for an associated entry in the Symbol Tables:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

package Foo;
1;

package main;
print "Data::Dumper was ", defined $Data::{'Dumper::'} ? "loaded\n" : 
+"not loaded\n";
print "Foo was ", defined $::{'Foo::'} ? "loaded\n" : "not loaded\n";
print "Eata::Dumper was ", defined $Eata::{'Dumper::'} ? "loaded\n" : 
+"not loaded\n";

This solution can be applied for any -M or -d. But, to the best of my understanding, the arguments themselves are lost to the ether.

[tobyink]

That's actually a pretty flaky technique.

use strict;
use warnings;
use Data::Dumper;

package Foo;
1;

package main;
print "Data::Dumper was ", defined $Data::{'Dumper::'} ? "loaded\n" : 
+"not loaded\n";
print "Foo was ", defined $::{'Foo::'} ? "loaded\n" : "not loaded\n";
print "Eata::Dumper was ", defined $Eata::{'Dumper::'} ? "loaded\n" : 
+"not loaded\n";

# Here's a false positive!
# "Data::Dumper" was loaded, and that makes it look like
# "Data" has also been loaded...
#
print "Data was ", defined $::{'Data::'} ? "loaded\n" : "not loaded\n"
+;

# Here's another false positive!
# When we checked if "Eata::Dumper" was loaded, 
# autovivification makes it look like "Eata" was loaded.
#
print "Eata was ", defined $::{'Eata::'} ? "loaded\n" : "not loaded\n"
+;

It's much better to check for the existence of the actual functions/methods you wish to use:

my $Dumper = UNIVERSAL::can('Data::Dumper', 'can')
             && 'Data::Dumper'->can('Dumper');
print $Dumper->($hashref) if defined $Dumper;