Replacing string with its length in Regex

[Brovnik]

I have a sub which converts e.g.

_________XX_X_XX_________ => 2,1,2
__________XXXXX__________ => 5
____XXXX___XXX__XXXXX____ => 4,3,5

Spec: output is comma separated list of run lengths of the 'X' parts.

The sub is :

sub template
{
   my $r = shift;
   $r =~ s/^_+//;
   $r =~ s/_+$//;
   $r =~ s/_+/_/g;
   return join ',', map { length($_) } split(/_/,$r);
}

Is there a Regex way of doing the last line ?
I'd like to be able to do e.g.

s/(X+)/length($1)/g;

But this if course doesn't do what I need.
--
Brovnik

[japhy]

You can execute code in the right-hand side of a substitution, by supplying the /e modifier.

s/(X+)/length $1/eg;

_____________________________________________________
Jeff japhy Pinyan: Perl, regex, and perl hacker.
s++=END;++y(;-P)}y js++=;shajsj<++y(p-q)}?print:??;

[bikeNomad]

Why not just:

my $s = s/_*(X+)_*/length($1) . ','/ge;
$s =~ s/,$//;

[petral]

even simpler:

$r =~ s/(^_+|_+$)//g;

$r =~ s/_+/,/g;

$r =~ s/(X+)/length$1/ge;

  p

[merlyn]

This smells a bit of being homework, but here's my answer:

sub template {
  return join ',', map length($_), shift =~ /(X+)/g;
}

-- Randal L. Schwartz, Perl hacker

[Brovnik]

Not homework honest.

It is part of a Nonogram Solver/manipulator. This sub is part of the file loader. I know that nonogram solvers have been given as homework in other places, and I wrote one in C++ some time ago, but thought I would rebuild it in Perl for fun.

This site gives more on Nonograms (also know as Paint by Numbers).
--
Brovnik

[Everlasting God]

Wow, so there is a name for the puzzles in picross! I take it the idea is to generate the number hints to a puzzle from an ascii bitmap?

'The fickle fascination of and Everlasting God' - Billy Corgan, The Smashing Pumpkins