Re^5: Space between digits

my $string = "(\d+)\:(\d+) (\d+)\/(\d+)\/(\d+)";

What is the purpose of this line? Does it really help you to do what you want to? What happens if you leave it out entirely?

s/// works in place (that is, on the variable it is bound to). What happens if you rewrite it as this:

if ($_ =~ m/(\d+)\:(\d+) (\d+)\/(\d+)\/(\d+)/ ){
    $_ =~ s/ /     /;
}
[download]

And of course, m// and s/// works on $_ in lieu of any other variable, so you could even just go:

if (m/(\d+)\:(\d+) (\d+)\/(\d+)\/(\d+)/ ){
    s/ /     /;
}
[download]

Which could be shortend to:

s/ /   / if  m/(\d+)\:(\d+) (\d+)\/(\d+)\/(\d+)/;
[download]

Those parens serve no purpose, as you're seemingly not capturing anything, so we can be even more briefer without harming readability:

s/ /   / if m/\d+\:\d+ \d+\/\d+\/\d+/;
[download]

Comment on Re^5: Space between digits Select or Download Code

Replies are listed 'Best First'.

Re^6: Space between digits
by AnomalousMonk (Archbishop) on Nov 23, 2012 at 04:56 UTC

s/ / / if m/\d+\:\d+ \d+\/\d+\/\d+/;

And because substitution is already conditional upon a match, the operation can easily be further briefened (if that's a word) and also made more specific and at the same time more general or global:

>perl -wMstrict -le
"my $string = '9 9 0:00 11/21/2012 12:34 01/23/2012 9 9';
 print qq{'$string'};
 ;;
 $string =~ s{ \d{1,2}:\d{2} \K [ ] (?= \d{2}/\d{2}/\d{2}) }
             {   }xmsg;
 print qq{'$string'};
"
'9 9 0:00 11/21/2012 12:34 01/23/2012 9 9'
'9 9 0:00   11/21/2012 12:34   01/23/2012 9 9'
[download]

The stage is now set to factor out the definitions of time and date, etc., so they can easily be made more specific, perhaps ultimately being able to reject things like a 'time' of 99:99 or a 'date' of 98/76/5432, or accept a date in the form of either 01/23/2012 or 2012/01/23, etc.

>perl -wMstrict -le
"my $string = '9 9 0:00 11/21/2012 12:34 01/23/2012 9 9';
 print qq{'$string'};
 ;;
 my $time = qr{ (?<! \d) \d{1,2} : \d{2}       (?! \d) }xms;
 my $date = qr{ (?<! \d) \d{2} / \d{2} / \d{4} (?! \d) }xms;
 ;;
 $string =~ s{ $time \K [ ] (?= $date) }{   }xmsg;
 print qq{'$string'};
"
'9 9 0:00 11/21/2012 12:34 01/23/2012 9 9'
'9 9 0:00   11/21/2012 12:34   01/23/2012 9 9'
[download]

[reply]
[d/l]
[select]


Problems? Is your data what you think it is?
	PerlMonks