Beefy Boxes and Bandwidth Generously Provided by pair Networks
Do you know where your variables are?
 
PerlMonks  

Re^2: pack/unpack binary file

by mark4444az (Sexton)
on Nov 30, 2012 at 13:55 UTC ( #1006479=note: print w/ replies, xml ) Need Help??


in reply to Re: pack/unpack binary file
in thread pack/unpack binary file

The reason I add newlines is so I can identify a certain element by where it is in the file and modify it. I'm more than likely making this harder than it needs to be due to inexperience. My current strategy is to unpack the bin file to a text file, select a value based on location, modify that value, then repack the text file. I believe I can do that by putting the output file in bin mode and then simply doing a pack, based on what I've read in this and other threads.


Comment on Re^2: pack/unpack binary file
Re^3: pack/unpack binary file
by johngg (Abbot) on Dec 01, 2012 at 00:11 UTC
    so I can identify a certain element by where it is in the file and modify it

    If you know where the element is you will know its offset into the binary file. I think sysopen, sysseek, sysread and syswrite might be what you want. You are dealing with Vax shorts so your record length is two bytes. Numbering records from zero means that to get to a certain record you sysseek to a position in the file two times its record number. Then you can either sysread two bytes and unpack them to get the value or pack a new value and syswrite the packed two byte string.

    Starting with the same binary file as before

    $ hexdump -C spw1006361.bin 00000000 00 00 01 00 02 00 03 00 04 00 05 00 06 00 07 00 |......... +.......| 00000010 08 00 09 00 0a 00 0b 00 0c 00 0d 00 0e 00 0f 00 |......... +.......| 00000020 10 00 11 00 12 00 13 00 14 00 15 00 16 00 17 00 |......... +.......| 00000030 18 00 19 00 1a 00 1b 00 1c 00 1d 00 1e 00 1f 00 |......... +.......| 00000040 $

    Running this script

    use strict; use warnings; use 5.014; use Fcntl qw{ :DEFAULT :seek }; use constant RECLEN => 2; my $binFile = q{spw1006361.bin}; sysopen my $binFH, $binFile, O_RDWR or die qq{sysopen: $binFile: $!\n}; my $origValue = readValue( $binFH, 7 ); say qq{Record 7 originally: $origValue}; writeValue( $binFH, 7, $origValue * 3 ); say qq{Record 7 now : @{ [ readValue( $binFH, 7 ) ] }}; close $binFH or die qq{sysopen: $binFile: $!\n}; sub readValue { my( $fh, $recNo ) = @_; sysseek $fh, $recNo * RECLEN, SEEK_SET or die qq{sysseek: $!\n}; my $bytesRead = sysread $fh, my $buffer, RECLEN; if ( not defined $bytesRead ) { die qq{sysread: $!\n}; } elsif ( $bytesRead == 0 ) { die qq{sysread: EOF\n}; } elsif ( $bytesRead != RECLEN ) { die qq{sysread: expected @{ [ RECLEN ] } bytes,}, qq{ got $bytesRead\n}; } else { return unpack q{v}, $buffer; } } sub writeValue { my( $fh, $recNo, $value ) = @_; sysseek $fh, $recNo * RECLEN, SEEK_SET or die qq{sysseek: $!\n}; my $bytesWritten = syswrite $fh, pack q{v}, $value; if ( not defined $bytesWritten ) { die qq{syswrite: $!\n}; } elsif ( $bytesWritten != RECLEN ) { die qq{syswrite: expected @{ [ RECLEN ] } bytes,}, qq{ wrote $bytesWritten\n}; } else { return; } }

    Produces this output

    ]$ ./spw1006361 Record 7 originally: 7 Record 7 now : 21 $

    The binary file now looks like this

    ]$ hexdump -C spw1006361.bin 00000000 00 00 01 00 02 00 03 00 04 00 05 00 06 00 15 00 |......... +.......| 00000010 08 00 09 00 0a 00 0b 00 0c 00 0d 00 0e 00 0f 00 |......... +.......| 00000020 10 00 11 00 12 00 13 00 14 00 15 00 16 00 17 00 |......... +.......| 00000030 18 00 19 00 1a 00 1b 00 1c 00 1d 00 1e 00 1f 00 |......... +.......| 00000040 $

    I hope this is heading in the right direction for you. Things will get more complicated if you want to delete records from the file or insert new ones but this functionality would not be too difficult to achieve.

    Cheers,

    JohnGG

Log In?
Username:
Password:

What's my password?
Create A New User
Node Status?
node history
Node Type: note [id://1006479]
help
Chatterbox?
and the web crawler heard nothing...

How do I use this? | Other CB clients
Other Users?
Others browsing the Monastery: (7)
As of 2014-12-18 01:24 GMT
Sections?
Information?
Find Nodes?
Leftovers?
    Voting Booth?

    Is guessing a good strategy for surviving in the IT business?





    Results (41 votes), past polls