Re: Compare CODE

[Athanasius]

in reply to Compare CODE

I think you pretty much answered your own question: B::Deparse seems to do just what you want:

#! perl
use Modern::Perl;

my ($foo, $bar, $baz, $mul, $op1, $op2);

my $cr1 = sub
{
    $foo = $bar * $baz;
};

my $cr2 = sub
{
    $foo = $bar *    $baz;   # Note whitespace differences
};

my $cr3 = sub
{
    $mul = $op1 * $op2;
};

my $cr4 = sub
{
    $foo = $baz * $bar;
};

compare_subs($cr1, $cr2);
compare_subs($cr3, $cr4);

sub compare_subs
{
    my ($s1, $s2) = @_;

    use B::Deparse;

    my $deparse = B::Deparse->new("-p", "-sC");
    my $body1   = $deparse->coderef2text($s1);
    my $body2   = $deparse->coderef2text($s2);

    if ($body1 eq $body2)
    {
        say 'Identical';
    }
    else
    {
        say 'Different';
    }
}

Output:

21:39 >perl 427_SoPW.pl
Identical
Different

21:40 >

So, the initial results look promising, at least!

Hope that helps,

[tobyink]

The only problem is closed-over variables...

use strict;
use warnings;
use B::Deparse;

sub make_multiplier {
    my $n = shift;
    return sub { $n * $_[0] };
}

my $double = make_multiplier(2);
my $treble = make_multiplier(3);

print "double and treble clearly do different things...\n";
print "double 5: ", $double->(5), "\n";
print "treble 5: ", $treble->(5), "\n\n";

my $deparse = B::Deparse->new;
$deparse->ambient_pragmas(strict => 'all', warnings => 'all');

print "yet, here is the B::Deparse output for double...\n";
print $deparse->coderef2text($double), "\n\n";

print "and here is the B::Deparse output for treble...\n";
print $deparse->coderef2text($treble), "\n";

__END__
double and treble clearly do different things...
double 5: 10
treble 5: 15

yet, here is the B::Deparse output for double...
{
    $n * $_[0];
}

and here is the B::Deparse output for treble...
{
    $n * $_[0];
}