how to merge hash deeply ?

[chinaxing]

I have two configure file defined by perl hash:

#file1: read as $conf_file1
{
   db => {
            name => 'pdte',
            host => 'localhost',
         }
}
#file2: read as $conf_file2
{   
   db => {
             port => '5432',
             user => 'pdte_usr',
             password => 'pdte_213456',
         }
}

my $new_conf = { %$conf_file1, %conf_file2 }

but this type of merge can only merge hash level1, cannot merge higher than level1.

How can i complete this merge in perl ?

[Kenosis]

One option is to use Hash::Merge:

use strict;
use warnings;
use Hash::Merge qw/merge/;
use Data::Dumper;

#file1: read as $conf_file1
my %hash1 = (
    db => {
        name => 'pdte',
        host => 'localhost',
    }
);

#file2: read as $conf_file2
my %hash2 = (
    db => {
        port     => '5432',
        user     => 'pdte_usr',
        password => 'pdte_213456',
    }
);

my %mergedHash = %{ merge( \%hash1, \%hash2 ) };

print Dumper \%mergedHash;

Output:

$VAR1 = {
          'db' => {
                    'password' => 'pdte_213456',
                    'user' => 'pdte_usr',
                    'name' => 'pdte',
                    'port' => '5432',
                    'host' => 'localhost'
                  }
        };

[chinaxing]

very thanks ! that's what i was finding

[Kenosis]

You're most welcome!

[Athanasius]

This is covered by How do I merge two hashes? in perlfaq4.

Hope that helps,

Update: Thanks to davido for pointing out that the FAQ cited doesn’t cover deep copying. Use the Hash::Merge solution by Kenosis for this.

[LanX]

For completeness:

if it's only the key db which matters

  DB<131> $conf3 = { db => { %{$conf1->{db}}, %{$conf2->{db}} } } 
=> 
{
  db => {
          host     => "localhost",
          name     => "pdte",
          password => "pdte_213456",
          port     => 5432,
          user     => "pdte_usr",
        },
}

and for the case that you have multiple keys which can also be missing in one of the hashes

  DB<132> $conf3 = { map { $_ => { %{$conf1->{$_}}, %{$conf2->{$_}} } 
+} keys %{{ %$conf1,  %$conf2 }} }
 => 
{
  db => {
          host     => "localhost",
          name     => "pdte",
          password => "pdte_213456",
          port     => 5432,
          user     => "pdte_usr",
        },
}

UPDATE

maybe easier to understand?

  DB<142> sub merge_hr {  return  { %{$_[0]}, %{$_[1]} } } 

  DB<143> $conf3 = { map { $_ => merge_hr( $conf1->{$_}, $conf2->{$_} 
+) } keys %{merge_hr($conf1,$conf2)} }
=> 
{
  db => {
          host     => "localhost",
          name     => "pdte",
          password => "pdte_213456",
          port     => 5432,
          user     => "pdte_usr",
        },
}