Retrieving Regex matched Group name

[Samman_Mahmoud]

Hii I want to get the matched group name after comparing string to regex expression

while($string=~m/(?<Word>(\w+)?<Digit>(\w+))/g)
{
print "Match : $1 GroupName: ";
}

[Kenosis]

If I'm understanding you correctly, it seems that you are attempting to use named capture groups and, if there's a match, retrieve the name of the matching group. If so, consider the following:

use strict;
use warnings;

my $string = 'word_one word_one word_two 2000 word_three 3000';

while ( $string =~ m/(?<Word>\w+)\s+(?<Digit>\w+)/g ) {
    my %groupNames;
    push @{ $groupNames{ $+{$_} } }, $_ for keys %+;
    print "Match : $1 GroupName(s): @{ $groupNames{$1} }\n";
}

Output:

Match : word_one GroupName(s): Word Digit
Match : word_two GroupName(s): Word
Match : word_three GroupName(s): Word

Group names and their associated values are contained in the hash %+. The above creates a hash of arrays (HoA) keyed on the (captured) values of %+, since two different keys may have identical values. The @{ $groupNames{$1} } notation uses the captured match as a key, and its associated value is the list of capture group names.

Hope this helps!

[Samman_Mahmoud]

ThanK U Kenosis that's exactly what I was Looking for :)

[Kenosis]

You're most welcome, Samman_Mahmoud!

[CountZero]

Please show us some of the strings you are trying to match. It is impossible to check whether the regex is correct if we do not see the input.

It would also be a helpful to tell what results you expect.

[LanX]

I suppose your question is how to get the name of a capture-group by index.

It's not easily possible to associate capture-name to capture-index. We had this recently.

Consider another concept!

But if you just want to know how to access the match for a name use %+

see perlretut: Outside of the pattern a named capture group is accessible through the %+ hash.

[frozenwithjoy]

Without knowing what you are trying to match, I'm just guessing, but my guess is that you want your regex to be something like this:

#!/usr/bin/env perl
use strict;
use warnings;
use feature 'say';

my $string = "<Word>Cat<Digit>1 blah blab blah <Word>Dog<Digit>0";

while ( $string =~ m/<Word>(\w+)<Digit>(\d+)/g ) {
    say "Matched Word: $1";
    say "Matched Digit: $2";
}

__END__
Matched Word: Cat
Matched Digit: 1
Matched Word: Dog
Matched Digit: 0