You want to use  +? as in \w+? , see perlfaq6, perlrequick

The akward to use and outdated YAPE::Regex::Explain can help explain

the problem (\w+)

the solution (\w+?)

search for "+?" and find perlfaq6#What does it mean that regexes are greedy? How can I get around it?

perlrequick doesn't mention "greedyness" but perlre#Quantifiers does

Why not split the string into chunks delimited by AAA, and then combine the chunks as you want and join them back?As in:

#!/usr/bin/perl -w

use strict;

my $string = shift || 'AAABCDAAADCBAAABBDAAA';
my @between = split /AAA/, $string, -1;
pop @between;
shift @between;

for (my $i = 0; $i<@between; $i++) {
    for (my $j = $i; $j<@between; $j++) {
        print join "AAA", "", @between[ $i .. $j ], "\n"
    };
};
[download]

This won't solve the problem if your string contains AAAA, though.

This looks to be exactly what I was looking for. I am going to try it on a few other test cases and see how it works. Thank you!

Here is a regex-based solution. As Anonymous Monk has pointed out, the non-greedy quantifier ? is an important component. But to get all the matches, you need to loop:

#! perl
use strict;
use warnings;

my %matches;
my $s = 'zzAAABCDAAADCBAAABBDAAA';
my $t = $s =~ s/^[^A]*?(AAA.*)/$1/r;

while ($t =~ /^AAA.+?AAA/)
{
    my $u = $t;

    while ($u =~ /^(AAA.+?AAA)/)
    {
        my $match = $1;
        $match =~ s/\|/AAA/g;
        ++$matches{$match};
        $u =~ s/(AAA.+?)AAA/$1\|/;
    }

    $t =~ s/^AAA.+?(AAA.*)/$1/;
}

print $_, "\n" for sort keys %matches;
[download]

Output:

 0:15 >perl 563_SoPW.pl
AAABBDAAA
AAABCDAAA
AAABCDAAADCBAAA
AAABCDAAADCBAAABBDAAA
AAADCBAAA
AAADCBAAABBDAAA

 0:23 >
[download]

The inner loop finds successively longer matches by changing the AAA at the end of each match into a non-word character. The outer loop truncates the search string by removing everything up to the second AAA.

Hope that helps,

#!/usr/bin/perl
use warnings;
use strict;
use feature qw(say);

my $string    = 'AAAbcdAAAdcbAAAbbdAAAxAAAA';
my $delimiter = 'AAA';
my @positions;
push @positions, pos($string) while $string =~ /(?=$delimiter)/g;
for my $from (@positions) {
    for my $to (grep $_ - length $delimiter > $from, @positions) {
        say substr($string, $from, $to - $from) . $delimiter;
    }
}
[download]

Update: Typo fixed. Thanks jaiieq, damn netbooks.

This is exactly what I needed. Which also gives me the ability to easily change the delimiter to say 'AA' and produce the output I need. Thank you.

There is a small typo in your code as you have a quote after $delimiter in the say line

Wow, substr is so much better here than split/join!