Re: Using variable to hold regex expression

[Kenosis]

in reply to Using variable to hold regex expression

Have you considered using Regexp::Common::net to capture those IPs?

use strict;
use warnings;
use Regexp::Common qw/net/;

while (<DATA>) {
    if ( my ( $firstIP, $secondIP ) = /($RE{net}{IPv4})/g ) {
        print "FirstIP: $firstIP\nSecondIP: $secondIP\n\n";
    }
}

__DATA__ 
Sample data Mar 10 07:42:38 DR-FW-1 : %ASA-6-305011: Built dynamic UDP
+ translation from inside:172.28.17.130/3324 to outside(internet-traff
+ic):69.176.102.83/24295
Sample data Mar 10 07:42:38 DR-FW-1 : %ASA-6-305011: Built dynamic UDP
+ translation from inside:155.0.42.42/3324 to outside(internet-traffic
+):71.200.20.7/24295

Output:

FirstIP: 172.28.17.130
SecondIP: 69.176.102.83

FirstIP: 155.0.42.42
SecondIP: 71.200.20.7

[salatconed]

Perhaps using IP addresses was not a good example, I'm trying to figure out how to parse a string which has repetitive data, so I can write the regex expression once and get multiple returns if they exist the same way your code got both IP addresses in one call.

[Kenosis]

If I'm understaing you correctly, the my ( $firstIP, $secondIP ) = /($RE{net}{IPv4})/g in the above code does what you've described.

[AnomalousMonk]

... how to parse a string which has repetitive data ...

As choroba pointed out, every  (pattern) pair of parentheses in a regex captures something (even undef possibly) to its corresponding capture variable. One way to parse a string using nested regexes is avoid using a gazillion capturing groups. Use the non-capturing  (?:pattern) instead for grouping. See perlre, perlrequick, perlretut. In the IP example (but this should generalize to any repetitive data you wish to extract):

>perl -wMstrict -le
"my $decimal_octet =
   qr{ 2 (?: [0-4] \d | 5 [0-5]) | [01]? \d? \d }xms;
 my $ip =
   qr{ (?<! \d) $decimal_octet (?: \. $decimal_octet){3} (?! \d) }xms;
 print $ip;
 ;;
 my $s = '123.45.6.234 xx yyy zz 000.12.34.255';
 my @ips = $s =~ m{ $ip }xmsg;
 printf qq{'$_' } for @ips;
"
(?^msx: (?<! \d) (?^msx: 2 (?: [0-4] \d | 5 [0-5]) | [01]? \d? \d ) (?
+: \. (?^msx: 2 (?: [0-4] \d |
5 [0-5]) | [01]? \d? \d )){3} (?! \d) )
'123.45.6.234' '000.12.34.255'

Note that neither  (?:pattern) nor the  (?<!pattern) (?!pattern) look-around assertions capture. Indeed, nothing captures (to a capture variable) since data is extracted in list context directly to an array.

[NodeReaper]

This node was taken out by the NodeReaper on Mar 14, 2013 at 22:57 UTC
Reason: [kcott]: Reap: duplicate of (1022903) Re^2: Using variable to hold regex expression.

You may view the original node and the consideration vote tally.