Re: Sort an array of strings based on two fields

[choroba]

in reply to Sort an array of strings based on two fields

The simple way is to write a code for sort which tells Perl how to compare two elements of the list:

#!/usr/bin/perl
use warnings;
use strict;
use feature qw(say);

my @strings = qw(xxxxxx.2012-50.yyyyy
                 xxxxxx.2012-51.yyyyy
                 xxxxxx.2012-52.yyyyy
                 xxxxxx.2013-1.yyyyy
                 xxxxxx.2013-2.yyyyy
                 xxxxxx.2013-3.yyyyy
                 xxxxxx.2013-4.yyyyy
                 xxxxxx.2013-10.yyyyy
                 xxxxxx.2013-11.yyyyy
                );

my @sorted = sort {
    my ($ay, $an) = $a =~ /\.([0-9]+)-([0-9]+)\./;
    my ($by, $bn) = $b =~ /\.([0-9]+)-([0-9]+)\./;
    $ay <=> $by or $an <=> $bn
} @string;

say for @sorted;

As this might be rather slow for larger lists, various technics exist to speed it up. One of them is called Orcish Maneuvre:

#!/usr/bin/perl
use warnings;
use strict;
use feature qw(say);

my @strings = qw(xxxxxx.2012-50.yyyyy
                 xxxxxx.2012-51.yyyyy
                 xxxxxx.2012-52.yyyyy
                 xxxxxx.2013-1.yyyyy
                 xxxxxx.2013-2.yyyyy
                 xxxxxx.2013-3.yyyyy
                 xxxxxx.2013-4.yyyyy
                 xxxxxx.2013-10.yyyyy
                 xxxxxx.2013-11.yyyyy
                );

my %cache;
my @sorted = sort {
    ($cache{$a} //= generate_key($a))
        cmp
    ($cache{$b} //= generate_key($b))
} @strings;

say for @sorted;

sub generate_key {
    my $s = (split /\./, shift)[1];
    my ($year, $number) = split /-/, $s;
    return $year . sprintf '-%03d', $number;
}

Update: Simple solution added.

[hdb]

As a small variant, you can calculate a key by 100*year+month, assuming that month will always be two digit at most...

my @sorted = sort {
    ($a =~ /\.([0-9]+)-([0-9]+)\./, 100*$1+$2) 
<=> ($b =~ /\.([0-9]+)-([0-9]+)\./, 100*$1+$2)
} @strings;

or would it be ok to insert the missing zero?

map { s/-(\d)\./-0\1./ } @strings;
my @sorted = sort @strings;

(Make sure the regexp does not match elsewhere in your strings.)

[choroba]

I assumed 3 digits in the second solution. 50 seems too big for a months to me (maybe a week?)